中文日期转数字日期

zjgwzj

经过测试，发现针对类似于“二○○九年九月二十一日”这样的中文日期，转换就不成功了。麻烦Sylun兄再对代码作一些改进，谢谢了。

kqbt

试了一下，对于包含“〇”的日期以及“日”为类似“二十一”这样的3位数时无法转换。

第Ⅸ夜

感谢各位大侠的参与，问题基本解决

sylun

我也是第一次用此转换方法，结果确实有点怪。刚才用上面的程序（常量strA相应调整为"[〇○一二三四五六七八九十]@"）对“二○○九年九月二十一日”进行转换结果为2009年9月22日，而“二〇〇九年九月二十一日”就无反应了，基本上是二十日后就相差一日，三十一日就无反应，但若将两者分别作为域代码并使用日期图片开关，他们又可正常转换的。以前只注意到用插入菜单插入“日期”和“数字”时，0转换为汉字小写数字时是不一样的字符。
我无法解释这一现象，看来用format函数直接对中文日期转换有问题。
以下改用间接的处理方法，还是用函数，代码要长些，看看效果如何：

Sub FormatDate2()
Const strA As String = "[〇○一二三四五六七八九十]@"
Const strB As String = "00123456789"
Dim temp As String, i As Byte
Application.ScreenUpdating = False
With ActiveDocument.Content.Find
    .MatchWildcards = True
    .Text = strA & "年" & strA & "月" & strA & "日"
    Do While .Execute
        With .Parent
            temp = Replace(.Text, "年", "-")
            temp = Replace(temp, "月", "-")
            temp = Replace(temp, "日", "")
            For i = 1 To 11
                temp = Replace(temp, Mid(strA, i + 1, 1), Mid(strB, i, 1))
            Next
            temp = Replace(temp, "-十-", "-10-")
            If temp Like "*-十" Then temp = Left(temp, Len(temp) - 1) & Replace(temp, "十", "10", Len(temp))
            If temp Like "*十" Then temp = Left(temp, Len(temp) - 1) & Replace(temp, "十", "0", Len(temp))
            temp = Replace(temp, "-十", "-1")
            temp = Replace(temp, "十", "")
            .Text = Format(temp, "yyyy年M月d日") '将字符串改为"yyyy-M-d"则为另一种格式
            .Collapse wdCollapseEnd
        End With
    Loop
End With
Application.ScreenUpdating = True
End Sub

[ 本帖最后由 sylun 于 2009-9-22 14:23 编辑 ]

第Ⅸ夜

〇○
这个一大一小是什么玩意？？？
format不行……上面的代码暂时米发现错误

kqbt

请问Sylun兄，我这里凡是日期中包含“〇”的为何都处理不了。
比如：“二〇〇二年十一月八日，中国共产党第十六次全国代表大会在北京举行。”
能够查找到，就是处理之后还是原来的大写日期格式。

sylun

不知kqbt用什么程序。14楼的代码好像可以处理。
如将代码再修改一下，好像还可以处理只有月日没有年份，或年份只用“去年”之类表示的日期。可试试：

Sub FormatDate3()
Const strA As String = "[〇○一二三四五六七八九十]@"
Const strB As String = "00123456789"
Dim temp As String, i As Byte
Application.ScreenUpdating = False
With ActiveDocument.Content.Find
    .MatchWildcards = True
    .Text = "[〇○一二三四五六七八九十年]@" & "月" & strA & "日"
    Do While .Execute
        With .Parent
            If .Text Like "年*" Then .Start = .Start + 1
            temp = Replace(.Text, "年", "-")
            temp = Replace(temp, "月", "-")
            temp = Replace(temp, "日", "")
            For i = 1 To 11
                temp = Replace(temp, Mid(strA, i + 1, 1), Mid(strB, i, 1))
            Next
            temp = Replace(temp, "-十-", "-10-")
            If temp Like "*-十" Then temp = Left(temp, Len(temp) - 1) & Replace(temp, "十", "10", Len(temp))
            If temp Like "*十" Then temp = Left(temp, Len(temp) - 1) & Replace(temp, "十", "0", Len(temp))
            If temp Like "十-*" Then temp = Replace(temp, "十", "10", 1, 1)
            If temp Like "十?-*" Then temp = Replace(temp, "十", "1", 1, 1)
            temp = Replace(temp, "-十", "-1")
            temp = Replace(temp, "十", "")
            If InStr(.Text, "年") Then .Text = Format(temp, "yyyy年M月d日") Else .Text = Format(temp, "M月d日")
            .Collapse wdCollapseEnd
        End With
    Loop
End With
Application.ScreenUpdating = True
End Sub

第Ⅸ夜

再问一边，你那一大一小俩圈是么东西？
怎么输入的？

tangqingfu

能否添加像“二零零九年九月二十一日”这样的中文日期的情况？

kqbt

谢谢Sylun兄！