关于从无规律字符串中取出数字的问题

blueee · 发表于 2009-9-2 21:33

a1=财务顾问费（5312）
a2=结汇手续费（5400）中的即期部分
a3=（6437）交易型手续费收入
希望在b1,b2,b3中输入公式，得到如下结果：b1=5312,b2=5400,b3=6437
a列单元格均为一些无规律的文字和数字的组合，请高手指点。

jtljy · 发表于 2009-9-2 21:39

b1=SUM(RIGHT(LARGE(IF(ISNUMBER(MID(A1,ROW($1:$20),1)*1),ROW($1:$20)*100+MID(A1,ROW($1:$20),1),0),ROW($1:$20)),1)*10^(ROW($1:$20)-1)) 数组公式

再补充一个容易理解的公式 b1=--MID(A1,FIND("（",A1)+1,FIND("）",A1)-FIND("（",A1)-1)

[ 本帖最后由 jtljy 于 2009-9-2 21:48 编辑 ]

wshcw · 发表于 2009-9-2 21:43

=-LOOKUP(1,-MID(A1,MIN(FIND({0;1;2;3;4;5;6;7;8;9},A1&5^19)),ROW($1:$15)))

zengyidin · 发表于 2009-9-2 21:44

供参考。。。
=LOOKUP(9^9,--MID(A1,FIND("（",A1)+1,COLUMN(A:Z)))

[ 本帖最后由 zengyidin 于 2009-9-3 08:12 编辑 ]

ZDYCTD · 发表于 2009-9-2 21:45

搞定了！！！

wshcw · 发表于 2009-9-2 21:47

这个数组公式比上一个通用性好多了,能取负值:
=LOOKUP(9^9,--RIGHT(LEFT(A1,MATCH(1,0/ISNUMBER(-MID(A1,COLUMN(1:1),1)))),ROW($1:$15)))

blueee · 发表于 2009-9-2 21:56

原帖由 wshcw 于 2009-9-2 21:47 发表
这个数组公式比上一个通用性好多了,能取负值:
=LOOKUP(9^9,--RIGHT(LEFT(A1,MATCH(1,0/ISNUMBER(-MID(A1,COLUMN(1:1),1)))),ROW($1:$15)))

斑竹能否帮忙讲解下这个数组公式，多谢.

wshcw · 发表于 2009-9-2 22:02

原帖由 blueee 于 2009-9-2 21:56 发表

斑竹能否帮忙讲解下这个数组公式，多谢.

先截取至最后一个数字,再从后面向左截取寒带的数字段.思路就是这样,只能这样解释了.

ajzdj · 发表于 2009-9-2 22:13

=MID(A1,MIN(IF(ISNUMBER(FIND({1,2,3,4,5,6,7,8,9,0},A1)),FIND({1,2,3,4,5,6,7,8,9,0},A1))),SUM(--ISNUMBER(FIND({1,2,3,4,5,6,7,8,9,0},A1))))数组公式。

ajzdj · 发表于 2009-9-2 22:32

请问，在这个公式中LOOKUP(1 的1是什么意思：=LOOKUP(1,--MID(A1,FIND("(",A1)+1,COLUMN(A:Z)))

		自动登录	找回密码
密码			免费注册

[2007] 关于从无规律字符串中取出数字的问题