菜鸟谈VBA最最基础入门《原创》

ggsmart

原帖由 宝贝有酒窝 于 2009-8-30 15:51 发表
我的作业
原本是想在利用字段调用子表合并到汇总表中的但是目前的技术实现不了
另外绿色底纹被我覆盖了……

底纹我只是给来作标记的，盖了没事。如果想不覆盖底纹，可以使用选择性粘贴或直接等于Value，都可以的。
对于你的代码，能实现需要得到的结果，但可以再完善一下。比如，其实程序中并不需要定义那么多的变量，也不用使用两层循环。这样只会让程序进行许多多余的计算，增加程序执行的时间。
楼上的jiminyanyan 朋友已经给你修改了一下，可以参考一下，但他在修改时，可能不小心把“为第三列(性别)添加数据的代码”删到了。我按照你的思路，把代码整理了一下（几乎和楼上的一样），供参考。
虽然我说了，只需要完成目的即可，但你你也可以看一下程序执行的时间，对比一下两次代码的区别，同样的思路，甚至是同样的语句，整理过的效率可是你原来的效率的七倍以上哦。
(回复)宝贝有酒窝的学生花名册汇总.rar (23.92 KB, 下载次数: 4071)

2009-8-30 18:12 上传

点击文件名下载附件

ggsmart

原帖由 moon2778 于 2009-8-30 10:46 发表
有需求就有市场是不是？ 我想学数组和类，诶。。。。

那下一贴就讲一讲数组吧。这段时间刚开学，需要做的事情好多，所以会慢点。
不过，也许还有些朋友没跟上来，当作等一等吧！

zzmdklhx

很好的总结

huangant

跟在后面慢慢追。。。

赵国辉

人的胸怀多大，能力就多大
走你的录，让别人vba吧！

ggsmart

VBA数组（一）

　　一、什么是数组
　　对于数组，在前面7楼的贴子里我们已经简单介绍了一些简单的概念，如果你忘记了，请回过头去花两分种读一读。
　　
　　读完了也许你还是不清楚，没关系，请接着往下看。
　　
　　新学期开始了，我上七（1）班数学，学生太多了，我老是记不住学生的名字，还好班主任为了便于管理，为班上的学生都编了学号，所以上课时点名我习惯性只点学生学号，我说，5号同学请上黑板演示一下你的解题过程，10号同学下课后请替老师把大家的作业收起来……下课后，在办公室，和大家聊天，我更不叫学生名字而直接统称为“七（1）班”。
　　待我学习了VBA的数组后，我忽然明白了，这种简化的称呼方式原来就是“数组”。
　　这里，我们是把一群学生聚在了一起组成了“七（1）班”（数组名）这个集合，班级里的学生我们通过“学号”（索引号）对其进行区分。上课时，我问：“5号同学是谁？”，一个同学站起来答：“我叫moon2778”，于是，我知道了，“七（1）班”这个数组里的第5个元素就是“moon2778”。用数组来表示就是“七（1）班(5)”，也就是数组名加索引号。好了，当别人果问你：“‘七（1）班(5)’的同学是谁？”时，你一定要知道，是“moon2778”。
　　那么，什么是数组，你知道了吧？它有什么特点，我们可以试着简单小结一下：
　　1、数组共享一个名字，即数组名；
　　2、数组是变量的集合，有多个元素；
　　3、数组中的元素按顺序保存在数组中，元素通过索引数字加以区分；
　　4、数组是变量。
　　
　　二、定义数组
　　声名数组同声明其他变量的方式一样，唯一不同的是数组有大小，包含多个单个变量。
　　初一学生报名入学后开始分班级，领导说，七（1）班分50个学生（确定了班级学生的个数最多只能有50个学生，再多一个都不行，因为没有座位了。），知道有50个学生后，老师拿到学生花名册就开始给学生编学号，建学籍。1号是谁？2号是谁？……50号是谁？
　　这就是一个定义数组，并给数组赋值的过程，用语句来表示，可以这样：
　　Dim 七（1）班(1 To 50)
　　七（1）班(1) = "张三"
　　七（1）班(2) = "李四"
　　七（1）班(3) = "王王"
　　.....
　　七（1）班(50) = "赵六"
　　这里，我们定义了一个50个元素的一维数组，并分别给数组的元素赋值。当然，这里用的只是一个模拟的语句。如果我们需要定义一个数组arr，存放1到100的整数集合，则代码为：
　　

1. 
   
2. 　　Sub ggsmart()
   
3. 　　  Dim arr(1 To 100) As Integer '声明数组名称及数据类型
   
4. 　　  For i = 1 To 100 '循环，为数组的元素赋值
   
5. 　　    arr(i) = i
   
6. 　　  Next
   
7. 　　End Sub
   
8. 　　

复制代码

　　其实“Dim arr(1 To 100) As Integer”我们也可以写成“Dim arr(99) As Integer”，这样，定义的数组同样是100个元素的一维数组，因为如果不指定起始索引号的话，VBA默认从0开始。
　　当然，你也是可以通过OPTION BASE 来修改数组默认的起始序号，在模块的第一句写上“OPTION BASE 1”这样，默认的数组起始序号就是1了。
　　
　　学习累了，恰好第二节课刚下，课间操时间，顺便可以到操场练练。可是，有些同学不认真啊，这不，老师在广播里叫上了：“七年级，（1）班的第五个同学请认真一点，七年级，（2）班的第三个同学注意队形……”
　　天了，我惊奇地发现，原来我们生活中有这么多“数组”，可是，你知道上面的这两个同学共享了一个什么名字吗？
　　是的，“七年级”就是它们共有的名字。
　　新生分班时，校长就说了，550名新生，每班50人，分成11个班，到各个班级里，老师都给学生分了学号（1到50号），11个班级就有11个1号，也有11个50号。晕，一个班的学生名字我都记不住，如果11个班的学生全站在一起，我该怎么称呼？
　　我高兴了，还好，我会数组。找到“moon2278”同学，我会说“七年级，1班，5号同学”，哈，难不了我。如果“宝贝有酒窝”同学是初一（9）班的25号，没关系，我也会说“七年级，9班，25号同学”。
　　哇，好简单，前面加个班级的序号区分就行了。
　　这里，“七年级”实际上是一个由11个一维数组（11个班）组成的二维数组，它的元素的个数是11*50（11个班，每个班级50名学生）个。习惯性，大家会说它是一个11*50的二维数组。
　　如果要写成代码，那就是：
　　Dim 七年级(1 To 11, 1 To 50)
　　七年级(1, 1) = "张三"
　　七年级(1, 2) = "李四"
　　'......
　　七年级(2, 1) = "钱林"
　　七年级(2, 50) = "林平"
　　'......
　　七年级(11, 50) = "周六"
　　我们说上面的数组是一个11*50的二维数组，放到表格里就相当于是一个11行50列的数组。
　　如果我们想定义一个二维数组，第一列存放1到100的奇数，第二列存放1到100的偶数，代码为：
　　

1. 
   
2. 　　Sub ggsmart()
   
3. 　　  Dim i As Integer, j As Integer
   
4. 　　  Dim arr(1 To 50, 1 To 2) As Integer '定义一个50*2的二维数组（50行，2列）
   
5. 　　  j = 1       '数组1 to 50的索引号
   
6. 　　    For i = 1 To 100 Step 2
   
7. 　　        arr(j, 1) = i  '奇数赋值
   
8. 　　        arr(j, 2) = i + 1 '偶数赋值
   
9. 　　        j = j + 1 '索引号加1
   
10. 　　Next
    
11. 　　[a1:b65536].Clear '清除原有数据
    
12. 　　[a1].Resize(50, 2) = arr '将数组赋值给A1单元格向下50行，向右2列的区域
    
13. 　　End Sub
    
14. 　　

复制代码

　　 1到100的奇偶数.rar (6.63 KB, 下载次数: 3272)

2009-8-31 12:13 上传

点击文件名下载附件

把代码复制到模块里，按F5可以看到程序运行的效果。
　　
　　上面，我们讲的是一维数组和二维数组，你也可以按同样的思路来理解三维、四维数组，甚至五维、六维……或者更多。
　　无非就是将称呼moon2278同学的方式改为“XX中学、七年级、1班、5号同学”或“XX市、XX中学、七年级、1班、5号同学”而已，如果你喜欢，你还可以将这个称呼扩展，随你了，这里不再举例。
　　
　　三、动态数组
　　声明一个数组，必须指定数组的大小，即它是几维数组，有多少个元素。
　　但有些时候，我们在定义数组的时候，并不能确定数组的大小，这时，我们在首次定义数组的时候括号内为空（当然先指定一个大小也是可以的，但纯属是多余），在程序过程中用Redim语句去重新指定数组的大小，这就是动态数组。
　　比如一个工作表的A列存储了学生姓名，现在我们需要把把有姓“张”的学生存储在数组arr中，预先我们并不知道A列姓张的学生有三十个还是五十个，所以，我们在定义时代码可以这样：
　　

1. 
   
2. 　　Sub ggsmart()
   
3. 　　  Dim i%, xrow%, j%, xcount%
   
4. 　　  Dim arr() As String
   
5. 　　  xrow = [a65536].End(3).Row '最后一个非空单元格行号
   
6. 　　  j = 1       '数组索引号
   
7. 　　  xcount = Application.WorksheetFunction.CountIf([a1:a65536], "张*") '统计有多少姓张的学生
   
8. 　　  ReDim arr(1 To xcount) '重新定义数组大小，元素共有xcount个
   
9. 　　  For i = 1 To xrow
   
10. 　　     If Left(Cells(i, 1).Value, 1) = "张" Then
    
11. 　　       arr(j) = Cells(i, 1).Value '给数组元素赋值
    
12. 　　       j = j + 1 '索引号加1
    
13. 　　     End If
    
14. 　　  Next i
    
15. 　　[b1:b65536].Clear '清除原有数据
    
16. 　　[b1].Resize(xcount, 1) = Application.WorksheetFunction.Transpose(arr) '将数组输入单元格区域
    
17. 　　End Sub
    
18. 　　

复制代码

　　 姓“张”的学生.rar (7.16 KB, 下载次数: 4046)

2009-8-31 12:13 上传

点击文件名下载附件

　　
　　四、其他创建数组的几种方式
　　其实在上面，我们已经接触了如何创建数组了。无非就是像给学生排座位一样，你坐第一排，我坐第二排，他坐第三排，然后你们大家统称为第一组。
　　好简单，这里，我再介绍几种上面没讲到，但常见的方法：
　　1、使用Array创建数组
　　看以下代码：
　　

1. 
   
2. 　　Sub ggsmart()
   
3. 　　  Dim arr()
   
4. 　　  arr = Array(1, 2, 3, 4, 5, 6, 7, 8, 9, 10) '将1到10十个自然数赋给数组arr
   
5. 　　  [a1].Resize(1, 10) = arr '将数组的值输入单元格
   
6. 　　End Sub
   
7. 　　

复制代码

　　这里使用Array函数将1到10的自然数赋给数组arr这里，我就不上传附件了，大家将代码复制到模块里查看效果。
　　

　　提醒一点：使用Array创建的数组索引号默认从0开始，当然，如果已经用“OPTION BASE 1”语句指定了的另当别论。
　　

　　需要提醒的是：如果赋的值是文本，那需要用英文引号引起来，如：
　　

1. 
   
2. 　　arr = Array("张祝", "徐国军", "陈茜", "王欢", "许松", "张小海", "陈飞", "张明元", "徐国东", "张款")
   
3. 　　

复制代码

　　2、使用Split创建数组
　　Split的作用是把一个文本，根据指定的分隔符，建立一个数组。感觉就有点像我们基础操作中的“分列”。不同的是“分列”操作是将一个单元格的文本按指定的分隔符分开，存放在同行的多个单元格里，而Split的作用是将一个文本（也可以是存放在单元格里的）按指定的分隔符分开，存放在一个数组变量里。
　　如果你使用过“分列”，再来看这个，就简单多了。
　　还是上面的那串姓名“张祝，徐国军，陈茜，王欢，许松，张小海，陈飞，张明元，徐国东，张款”，只是这时，这些姓名是一个完整的字符串，此时，如果我们想把这些姓号按逗号（，）分开，存放在数组arr里，则代码为：
　　

1. 
   
2. 　　arr = Split("张祝，徐国军，陈茜，王欢，许松，张小海，陈飞，张明元，徐国东，张款", "，")
   
3. 　　

复制代码

　　你可以用上面的方式将生成的数组输入到单元格查看效果。当然，也可以在立即窗口里查看，这样就更方便了。
　　特别强调一点：用Split把文本转换成数组，索引号总是从0开始。不管你是否使用了Option Base语句，这点和Array不同。
　　3、通过Range创建数组
　　（1）循环给单元格赋值
　　比如想把A1:A100单元格的值给数组arr，则代码为：
　　

1. 
   
2. 　　Sub a()
   
3. 　　  Dim arr(1 To 100)
   
4. 　　    For i = 1 To 100
   
5. 　　       arr(i) = Cells(i, 1)
   
6. 　　    Next
   
7. 　　End Sub
   
8. 　　

复制代码

　　(2)直接等于单元格区域
　　这个很简单，直接数组名等于单元格区域就可以了。
　　比如想把A1:A100单元格的值给数组arr，代码还可以简单写为：
　　

1. 
   
2. 　　arr = [a1:a100]
   
3. 　　

复制代码

　　好了，很简单，我就不再多说，大家自己去练习吧。
　　两种方法哪种的效率高显而易见吧？呵呵……有兴趣，可以自己去比较一下。
　　五、UBount和LBound函数
　　我们定义数组时，我们可以指定数组的起始索引号不为0，而为1或其他的任意数。比如Dim arr(5 to 6)定义的这个数组起始索引号为5,共有两个元素。
　　那么，对于一个已经定义了的数组，我们想知道它的最大索引号（上界）和最小索引号（下界）是多少，怎么办呢？别慌，用UBound和LBound两个函数就可以了。
　　如，要想知道数组arr的上界是多少，则：UBound(arr)
　　要想知道数组arr的下界是多少，则：LBound(arr)
　　想知道数组有多少个元素，则：UBound(arr)- LBound(arr)+1
　　如：
　　

1. 
   
2. 　　Sub ggsmart()
   
3. 　　 Dim arr(10 To 50)
   
4. 　　 MsgBox "数组的上标是：" & UBound(arr) & Chr(13) _
   
5. 　　        & "数组的下标是：" & LBound(arr) & Chr(13) _
   
6. 　　        & "数组的元素个数是：" & UBound(arr) - LBound(arr) + 1
   
7. 　　End Sub
   
8. 　　

复制代码

　　如果是一个二维数组，想知道它的上界是多少，就得指定维数，看一看下面的例子：
　　

1. 
   
2. 　　Sub ggmsart()
   
3. 　　  Dim arr(1 To 10, 1 To 100)
   
4. 　　  MsgBox "第一维的上界是:" & UBound(arr, 1) & Chr(13) & _
   
5. 　　         "第二维的上界是:" & UBound(arr, 2)
   
6. 　　End Sub
   
7. 　　

复制代码

　　六、Join函数
　　Join的作用和Split的作用相反。Split是将字符按指定字符转为数组，Join是将数组以指定字符分开，连成一个字符串。如：
　　

1. 
   
2. 　　Sub ggsmart()
   
3. 　　  Dim arr(1 To 10), i As Integer, txt As String
   
4. 　　  For i = 1 To 10 '给数组赋值
   
5. 　　    arr(i) = i
   
6. 　　  Next i
   
7. 　　  txt = Join(arr, ",") '将arr数组的元素连成字符串，用逗号作分隔符
   
8. 　　  MsgBox txt
   
9. 　　End Sub
   
10. 　　

复制代码

　　Join的第二参数，即分隔符可以不指定，在不指定时，默认为以空格作分隔符。
　　七、将数组输入单元格区域
　　1、使用循环输入
　　如将存储了1到60000的数的数组写入A列，则：
　　

1. 
   
2. 　　Sub test1()
   
3. 　　 '创建数组，并赋值
   
4. 　　 Dim arr(1 To 60000), i As Long
   
5. 　　 For i = 1 To 60000
   
6. 　　     arr(i) = i
   
7. 　　 Next i
   
8. 　　 '将数组的值写入单元格（A列）
   
9. 　　 [a1:a65536].Clear '清除原有数据
   
10. 　　 Dim irow As Long
    
11. 　　 Dim startime As Double
    
12. 　　 startime = Timer
    
13. 　　 For irow = 1 To 60000
    
14. 　　     Cells(irow, 1) = arr(irow)
    
15. 　　 Next irow
    
16. 　　 MsgBox "数组写入共用了" & Timer - startime & "秒！"
    
17. 　　End Sub
    
18. 　　

复制代码

　　以上程序是使用循环，将数组里的元素逐个写入单元格，为了对比不同的输入方式的效率，我加入了计算时间的代码，有了前面的基础，相信读上面的代码对大家来说，不会太困难。
　　2、批量写入
　　实际上用一条语句就可以将数的内容写入单元格区域中，即：单元格区域=数组名
　　还是上面的例子，我们可改为：
　　

1. 
   
2. 　　Sub test2()
   
3. 　　 '创建数组，并赋值
   
4. 　　 Dim arr(1 To 60000), i As Long
   
5. 　　 For i = 1 To 60000
   
6. 　　     arr(i) = i
   
7. 　　 Next i
   
8. 　　 '将数组的值写入单元格（A列）
   
9. 　　 [a1:a65536].Clear '清除原有数据
   
10. 　　 Dim startime As Double
    
11. 　　 startime = Timer
    
12. 　　 [a1:a60000] = Application.WorksheetFunction.Transpose(arr)
    
13. 　　 MsgBox "数组写入共用了" & Timer - startime & "秒！"
    
14. 　　End Sub
    
15. 　　

复制代码

　　这里，我们用“[a1:a60000] = Application.WorksheetFunction.Transpose(arr)”代替了上面代码For循环，在我的电脑上，程序的效率就提高了25倍以上。 数组写入单元格.rar (8.04 KB, 下载次数: 2755)

2009-8-31 12:13 上传

点击文件名下载附件

所以在大批量的数据需要写入时，我建议尽量不要用循环的方式写入。
　　这种批量写入的方式在上面的例子里其实我已经用到了，相信大家不会陌生。
　　这里，我再补充两点我个人在学习过程中的心得：
　　（1）一维数组写入单元格区域时，这个单元格必须是水平方向的，也就是一个一行多列的单元格区域，如果想写入垂直区域，必须使用工作表的Transpose函数转换一下；
　　（2）和工作表的多单元格数组公式一样，数组写入单元格时，单元格的区域必须和数组的大小一致。
　　
　　
　　

[ 本帖最后由 ggsmart 于 2009-8-31 12:21 编辑 ]

yj0715

楼主的强帖很受教。不过其中的附件很分散，能集中一处下载吗，谢谢

oxwolf

讲的太好了~~~~~~~~~~~~

lebesgue

谢谢楼主发这么好的教程！看了之后很受益！

stella_xiaoxia

原帖由 jiminyanyan 于 2009-8-30 17:45 发表

Sub mysub()
  Dim start As Double, sh As Worksheet, B As Integer, j As Integer
  start = Timer
  Application.ScreenUpdating = False
  Sheets("外在本就读花名册").Range("b3:f65536") = ""
  For Ea ...

非常弱的问下，sh.Range("b3 :b" & B)这句能解释下吗，不是很明白的。。。