(( 一直未解决))如何禁止修改页眉页脚！

yqdfd

CommandBars.DisableCustomize = True '禁用所有自定义,XP及以上,包括双击工具栏等
.CommandBars("toolbar list").Enabled = True  '右击禁用

难道就没 有一句代码可以禁用自 定义页眉嘛?

zldccmx

既然要这样，那就来狠的！

一、插入一个标准模块，粘贴如下代码
      '撰写:老朽
      '网址:http://Club.ExcelHome.net
      '日期:2009-8-23 上午 11:40:25
Sub 设置所有打印相关功能(Allow As Boolean )
    With Application
        For Each cb In .CommandBars(1).Controls(3).Controls    '视图菜单下的页眉和页脚
            If cb.Caption Like "页眉和页脚*" Then cb.Enabled = Allow: Exit For
        Next
        For Each cb In .CommandBars(1).Controls(1).Controls    '文件菜单下的相关打印功能
            If cb.Caption Like "页面设置*" Or cb.Caption Like "打印预览*" Or cb.Caption Like "打印(*" Then cb.Enabled = Allow
            '打印区域设置没有禁用
            '如果要一并禁用的话就用这一句代替上面一句： If cb.Caption Like "页面设置*" Or cb.Caption Like "打印*"  Then cb.Enabled = Allow
        Next
        For Each cb In .CommandBars("Standard").Controls    '工具栏中的打印、打印预览按钮设置
            If cb.Caption Like "打印*" Then cb.Enabled = Allow
        Next
        .CommandBars.DisableCustomize = Not Allow  '禁用所有自定义,包括双击工具栏等
        .CommandBars("Toolbar list").Enabled = Not Allow  '右击禁用
    End With
End Sub

      '撰写:老朽
      '网址:http://Club.ExcelHome.net
      '日期:2009-8-23 上午 11:40:25
Sub 人工调用打印()
    ActiveSheet.PrintOut
End Sub

zldccmx

二、在THISKWORKBOOK的代码区，粘贴如下代码：
      '撰写:老朽
      '网址:http://Club.ExcelHome.net
      '日期:2009-8-23 上午 11:36:08
Private Sub Workbook_BeforeClose(Cancel As Boolean )
    Call 设置所有打印相关功能(True)
End Sub
      '撰写:老朽
      '网址:http://Club.ExcelHome.net
      '日期:2009-8-23 上午 11:36:09
Private Sub Workbook_Open()
    Call 设置所有打印相关功能(False)
End Sub

zldccmx

三、在你需要打印的工作表中，只能通过按钮来调用如下宏

1. 
   
2. Sub 人工调用打印()
   
3.     ActiveSheet.PrintOut
   
4. End Sub

复制代码

即　Call 人工调用打印

yqdfd

谢谢老朽!!

zldccmx

也可以这样来打造带参数的打印宏
      '撰写:老朽
      '网址:http://Club.ExcelHome.net
      '日期:2009-8-23 下午 12:15:42
Sub 人工调用打印(Sh As Object , Optional From, Optional T_o, Optional Copies)
    On Error Resume Next
    If IsMissing(From) Then From = 1
    If IsMissing(T_o) Then
        Sh.PrintOut From, , Copies
    Else
        Sh.PrintOut From, T_o, Copies
    End If
End Sub


      '撰写:老朽
      '网址:http://Club.ExcelHome.net
      '日期:2009-8-23 下午 12:15:42
Sub Test()
    Call 人工调用打印(Worksheets("Sheet1"), , , 2)
End Sub

zldccmx

'Sh ：需要打印的对象
'From：起始页
'T_o：终止页
'Copies：打印份数