急!求助快速去除公式和宏代码的方法!!!

tianteng

如果一个工作簿里有很多个工作表,每个工作表内都有公式和宏代码,请问有没有办法在另存为其他文件名的时候快速去除公式和宏代码的方法呀,我现在是每次另存都一个个工作表中去删除宏代码,然后用选择性粘贴的方法去去除公式,这种文件一多,工作量就太大了,请高手帮帮忙想想,有没有什么简便的方法呀!!!

Tq-laoyu

宏代码有没有密码保护？

Tq-laoyu

With Sheets(1)
.UsedRange.Value = .UsedRange.Value
End With

以上代码可以将公式变为数值，可以通过循环处理所有工作表，例如
Sub dd()
Dim i As Integer
For i = 1 To Sheets.Count
    With Sheets(i)
    .UsedRange.Value = .UsedRange.Value
    End With
Next
End Sub

tianteng

宏代码有密码保护，难道没有密码保护就可以破解吗，怎么做啊，高手教我啊！

Tq-laoyu

这个比较难。首先需要设置excel的宏安全性，信任对于vb项目的访问（当然这也是可以用代码完成的），然后引用vb for applications extensibility 库。

清除代码的代码如下：
Sub crac()
Dim wk As String
Dim wb As Workbook
wk = Application.GetOpenFilename(filefilter:="Excel文件,*.xls")
Set wb = Workbooks.Open(wk)
removevba wb
wb.Close savechanges:=True
MsgBox "代码已清除"
End Sub



Public Sub removevba(wbk As Workbook)
Dim i As Long
Dim vbc As VBComponent
For Each vbc In wbk.VBProject.VBComponents
    If vbc.Type = vbext_ct_Document Then
        vbc.CodeModule.DeleteLines 1, vbc.CodeModule.CountOfLines
    Else
        wbk.VBProject.VBComponents.Remove vbc
    End If
Next vbc
End Sub

tianteng

Tq-laoyu  你的方法很有效，没有密码保护的一些文件，代码真的被清掉了，太感谢了，

那我再问一下，有密码的能不能清掉啊，

Tq-laoyu

有密码保护也可以！

tianteng

高手，请你一定要教我啊，我被这个问题搞了好几天了，找不到答案啊！

Tq-laoyu

Public Sub removevba(wbk As Workbook)
Dim i As Long
Dim vbc As VBComponent
Dim passwd As String
Application.VBE.MainWindow.Visible = False
passwd = "123456" '密码变量
If wbk.VBProject.Protection = vbext_pp_locked Then
    Application.VBE.CommandBars.FindControl(ID:=2578).Execute
    SendKeys passwd & "{ENTER}"
    SendKeys "{ENTER}"
    DoEvents
End IfFor Each vbc In wbk.VBProject.VBComponents
    If vbc.Type = vbext_ct_Document Then
        vbc.CodeModule.DeleteLines 1, vbc.CodeModule.CountOfLines
    Else
        wbk.VBProject.VBComponents.Remove vbc
    End If
Next vbc
End Sub

tianteng

太感谢了！