是否可以实现自动添加收件人的功能？

fanny_6

我每天的进出邮件太多了，本地根本存不下了。另外也考虑到安全问题，想在公网备份一下收到的和发出的邮件。
备份收到的邮件很简单，在公网邮箱上设置一个POP就可以了。
如何备份发出的邮件呢？
我的思路是每次都自动暗送一份给自己的公网邮箱。
以前用的是foxmail，这个问题根本无法解决。
刚刚才发现office outlook有vba的，如果这样，实现自动暗送是不是就容易了，有没有现成的代码？谢谢。

fanny_6

谢谢，明天试试

fanny_6

这样写了，邮件会在发件箱里，如果加Item.Send会报错，说不能处理正在发送的邮件，怎么办？

fanny_6

我觉得不应该是在点击发送后才发生的事件，即使item.send成功了，发件箱里也会有两封相同的邮件。
是不是可以在点击“新建”、“转发”、“回复”时，添加暗送收件人？

aaaaabbbbb

请把你添加的代码界面拷贝出来看看。

fanny_6

我就把Long_III提供的代码粘到THISOUTLOOKSESSION
中了。
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
         Item.BCC = "xxx@xxx.com"
End Sub
其结果是发送的邮件发出了，暗送的发不出，且发件箱的那封邮件还在。这封邮件不论是直接点发送/接收按钮，还是打开邮件点击发送都发不出去。

如果改成如下代码：
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
        item.subject="123"
End Sub
主题修改成功，邮件发出。
请版主帮忙分析一下原因，谢谢

aaaaabbbbb

从帮助里可以看出“此属性仅包含显示名称。若要修改密件抄送收件人，应使用 Recipients 集合。
=================＝＝＝＝
Outlook 开发人员参考
MailItem.BCC 属性
返回 MailItem 的密件抄送 (BCC) 名称的显示列表。String 类型。可读写。
语法

表达式.BCC

表达式   一个代表 MailItem 对象的变量。

说明

mailitem.bcc属性仅包含显示名称。若要修改密件抄送收件人，应使用 Recipients 集合。
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
而mailitem.subject属性参考如下：

Outlook 开发人员参考
MailItem.Subject 属性
返回或设置一个 String 类型的值，指示 Outlook 项目的主题。可读写。
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
因此，代码要修改。

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objRecip As Recipient
    Dim strMsg As String
    Dim res As Integer
    Dim strBcc As String
    On Error Resume Next

    strBcc = "***@sina.com" '请改成你要密送的邮件地址

    Set objRecip = Item.Recipients.Add(strBcc)
    objRecip.Type = olBCC
    If Not objRecip.Resolve Then
        strMsg = "不能解析密件抄送人邮件地址， " & _
                 "请确认是否仍然发送邮件？"
        res = MsgBox(strMsg, vbYesNo + vbDefaultButton1, _
                "不能解析密件抄送人邮件地址")
        If res = vbNo Then
            Cancel = True
        End If
    End If

    Set objRecip = Nothing

End Sub

[ 本帖最后由 aaaaabbbbb 于 2008-12-20 17:09 编辑 ]

fanny_6

成功了，谢谢

Long_III

试试如下代码
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
         Item.BCC = "xxx@xxx.com"
End Sub

qingyezi

太感谢了,成功了.要降低outlook关于宏的安全性