[求助]如何批量接受多篇Word文档中的修订标记？（已解决）

wxg

终于解决了

[此贴子已经被作者于2008-4-9 16:49:15编辑过]

wxg

现在已经找到了框架，问题是如何用VBA代码表示接受myRange中的修订标记？
即"myRange." + "接受修订标记的代码"
捣鼓了一晚上，也没弄明白怎么用代码写出这个操作，嘿嘿，太笨了，希望老师们指点一下，谢谢了。

sylun

这是帮助文件的解释：

AcceptAll 方法

接受某一文档或区域中的所有修订。修订标记将被删除，修订将合并到文档中。

expression.AcceptAll

expression      必需。返回 Revision 对象的表达式。

说明

应用 AcceptAllRevisions 方法来接受文档中的所有修订。

示例

本示例接受活动文档中的所有修订。

If ActiveDocument.Revisions.Count >= 1 Then _

ActiveDocument.Revisions.AcceptAll

本示例接受所选内容中的所有修订。

Selection.Range.Revisions.AcceptAll

[此贴子已经被作者于2008-4-9 14:11:34编辑过]

wxg

谢谢sylun老师的解答，在您的帮助下，问题解决了，我把守柔版主的框架搬过来，比着葫芦画瓢，终于做成了能够完成任务的宏。
代码如下：
Sub acceptrevisions()    '此代码功能为列出指定文件夹中所有选取的WORD文件全路径名
    Dim myDialog As FileDialog, oDoc As Document, oSec As Section
    Dim oFile As Variant, myRange As Range
    On Error Resume Next
    '定义一个文件夹选取对话框
    Set myDialog = Application.FileDialog(msoFileDialogFilePicker)
    With myDialog
        .Filters.Clear    '清除所有文件筛选器中的项目
        .Filters.Add "所有 WORD 文件", "*.doc", 1    '增加筛选器的项目为所有WORD文件
        .AllowMultiSelect = True    '允许多项选择
        If .Show = -1 Then    '确定
            For Each oFile In .SelectedItems    '在所有选取项目中循环
                Set oDoc = Word.Documents.Open(FileName:=oFile, Visible:=False)
                For Each oSec In oDoc.Sections    '文档的节中循环
                    Set myRange = oSec.Range
                    myRange.Revisions.AcceptAll   '接受所选范围内的所有修订标记
                Next
                oDoc.Close True
            Next
        End If
    End With
End Sub

已经通过试验，运行效果很好，只是其中还有些冗余的代码，自己又不会修改，哪位老师再帮忙精简一下，谢谢喽++++

sylun

我也是VBA的初学者，不是老师。只是学习时常用录制与查看帮助文件，觉得如此做法很多问题有可能自行解决。帮助文件是最好的老师。

看代码似是接受对全文档的修订。如果是这样，可试删除下面几句而只用oDoc.Revisions.AcceptAll：
For Each oSec In oDoc.Sections
    Set myRange = oSec.Range
    myRange.Revisions.AcceptAll
Next

wxg

试过了，果然可以，Thank you ++++

守柔

QUOTE:

以下是引用sylun在2008-4-9 14:10:27的发言：

这是帮助文件的解释：

AcceptAll 方法

接受某一文档或区域中的所有修订。修订标记将被删除，修订将合并到文档中。

expression.AcceptAll

expression      必需。返回 Revision 对象的表达式。

说明

应用 AcceptAllRevisions 方法来接受文档中的所有修订。

示例

本示例接受活动文档中的所有修订。

If ActiveDocument.Revisions.Count >= 1 Then _

ActiveDocument.Revisions.AcceptAll

本示例接受所选内容中的所有修订。

Selection.Range.Revisions.AcceptAll

既然是接受文档中所有修订者的所有修订，则可以直接应用AcceptAllRevisions方法，而无需遍历节区域。

For Each oFile In .SelectedItems    
                Set oDoc = Word.Documents.Open(FileName:=oFile, Visible:=False)
                oDoc.AcceptAllRevisions
                oDoc.Close True
Next

wxg

谢谢守柔版主，这是最后经过精简的版本：

 Sub acceptrevisions()    '此代码功能为列出指定文件夹中所有选取的WORD文件全路径名
    Dim myDialog As FileDialog, oDoc As Document
    Dim oFile As Variant
    On Error Resume Next
    '定义一个文件夹选取对话框
    Set myDialog = Application.FileDialog(msoFileDialogFilePicker)
    With myDialog
        .Filters.Clear    '清除所有文件筛选器中的项目
        .Filters.Add "所有 WORD 文件", "*.doc", 1    '增加筛选器的项目为所有WORD文件
        .AllowMultiSelect = True    '允许多项选择
        If .Show = -1 Then    '确定
            For Each oFile In .SelectedItems    '在所有选取项目中循环
                Set oDoc = Word.Documents.Open(FileName:=oFile, Visible:=False)
                oDoc.Revisions.AcceptAll
                oDoc.Close True
            Next
        End If
    End With
End Sub

应该没啥问题了吧？

正在学习您的《Word非常接触》，受益非浅+++++++

[此贴子已经被作者于2008-4-10 8:18:55编辑过]

wxg

今后一定要多看Word的帮助文件+++++

[em04][em04][em04]

sylun

老大的代码更加精确到位，即将oDoc.Revisions.AcceptAll改为oDoc.AcceptAllRevisions