如何判断excel中的单元格是否在编辑状态

fecmen

QUOTE:

以下是引用wangminbai在2008-2-2 14:25:50的发言：

使用钩子函数应该可以判断的，以下代码就是当处于编辑状态时在Excel的状态栏上显示 正处于编辑状态……

 

'**********************************************************************************************************
'**********************************************************************************************************
'//取得类名
Private Declare Function GetClassName _
    Lib "user32" _
    Alias "GetClassNameA" ( _
        ByVal hwnd As Long, _
        ByVal lpClassName As String, _
        ByVal nMaxCount As Long) _
As Long
'//设置钩子函数
Public Declare Function SetWindowsHookEx _
    Lib "user32" _
    Alias "SetWindowsHookExA" ( _
        ByVal idHook As Long, _
        ByVal lpfn As Long, _
        ByVal hmod As Long, _
        ByVal dwThreadId As Long) _
As Long
'//结束钩子
Public Declare Function UnhookWindowsHookEx _
    Lib "user32" ( _
        ByVal hHook As Long) _
As Long
'//下一个钩子
Public Declare Function CallNextHookEx _
    Lib "user32" ( _
        ByVal hHook As Long, _
        ByVal nCode As Long, _
        ByVal wParam As Long, _
        lparam As Any) _
As Long
'//取得当前线程的ID
Public Declare Function GetCurrentThreadId _
    Lib "kernel32" () _
As Long

Public Const HCBT_SETFOCUS = 9
Public Const WH_CBT = 5
Public IHook As Long
Public IThreadId As Long
Public ClassName As String
'-------设置钩子-----------
Public Sub EnableHook()
    If IHook = 0 Then
        IThreadId = GetCurrentThreadId
        IHook = SetWindowsHookEx(WH_CBT, AddressOf HookProc, Application.Hinstance, IThreadId)
    End If
End Sub
'-------取消钩子-----------
Public Sub FreeHook()
    If IHook <> 0 Then
        Call UnhookWindowsHookEx(IHook)
        IHook = 0
    End If
End Sub
'---------回调----------------
Public Function HookProc(ByVal nCode As Long, ByVal wParam As Long, ByVal lparam As Long) As Long
    If nCode < 0 Then
        HookProc = CallNextHookEx(IHook, nCode, wParam, lparam)
        Exit Function
    End If
    If nCode = HCBT_SETFOCUS Then
        ClassName = String(255, Chr(0))
        GetClassName wParam, ClassName, 255
        ClassName = Left(ClassName, InStr(ClassName, vbNullChar) - 1)
        If ClassName = "EXCEL<" Or ClassName = "EXCEL6" Then
            Application.StatusBar = "正处于编辑状态……"
        Else
            Application.StatusBar = False
        End If
    End If
    HookProc = CallNextHookEx(IHook, nCode, wParam, lparam)
End Function

 

真不错啊！顶！！

xxlzg

不需要，只要在操作前激活excel发送一个esc就行了，不管单元格是否在编辑状态

jhj2002

QUOTE:

以下是引用xxlzg在2008-2-3 10:26:05的发言：
不需要，只要在操作前激活excel发送一个esc就行了，不管单元格是否在编辑状态

比如你打开"查找"对话框的时候,即使是编辑状态,用sendkey的话,可能就关闭对话框了.但还是编辑状态.

[此贴子已经被作者于2008-2-3 10:55:12编辑过]

liuyanjiu

QUOTE:

以下是引用xxlzg在2008-2-2 9:02:56的发言：

下面的好像没用

返回或设置“数据输入”模式，如下表所示。处于“数据输入”模式时，仅可在当前选定区域的未锁定单元格中输入数据。Long 类型，可读写。

值	含义
xlOn	“数据输入”模式处于打开状态。
xlOff	“数据输入”模式处于关闭状态。
xlStrict	“数据输入”模式处于打开状态，并且按 Esc 时不关闭数据输入模式。

示例

本示例检查“数据输入”模式是否处于打开状态，如果是，则关闭之。

If (Application.DataEntryMode = xlOn) Or _
    (Application.DataEntryMode = xlStrict) Then
        Application.DataEntryMode = xlOff
End If
 

请问用的你方法能锁定有值的单元格吗？如果没有值则为编辑模式。

hhzjxss

呵呵，搞了半天才明白楼主是要有VB中，不是VBA中！

liimtj

学习了  原来如此

mumushu

谢谢wangminbai！

luckberry

可以参考这个兄弟的方法。虽然计时器在编辑状态下没实时显示，但是时间是在运行的。
http://club.excelhome.net/thread-1079254-1-1.html

tongkj

xxlzg 发表于 2008-2-2 11:34
我找到方法了用vb的appactivate激活excel然后发送一个sendkey esc

1. Public Function EndEdit()
   
2.     AppActivate "Microsoft Excel"
   
3.     xlApp.SendKeys "{ESC}"
   
4. End Function
   

复制代码

我用这样操作可以吗

撒网计划

BeforeDoubleClick 触发可以判断进入 数据输入模式。 输入完成后，会有个 Change。就是你不修改，进去就退出，也会触发的。