[开_107]字符串末尾连续个数

willin2000

题目:

求各字符串最后一个字母/数字之连续个数,用一条可下拉的公式求出结果,数据如下:

数据和结果:

数据	答题公式	答案
EXCELHOME 会员越340000		4
EH 从000000开始 到340000		4
19992000200700		2
1999年成立EXCELHOMEEE		3
EH从 无 到兴旺		5
EH从无到兴旺旺旺旺旺旺		6
你知道EH吗???????		7
****EH我喜欢 :( ****		4
旺旺旺旺旺旺旺旺旺		9
33		2
1		1
0		1
??		2
?		1
*		1
0*		1

评分规则:
1.截止日期2007/10/7 23:00 该时间以后的答案不评分
2.结果错误不得分.
3.答案正确评1-2分.
4.最短答案+1分(总结时再加)
5.精彩答案+1分.(不一定时最短)
6.思路有新意+1分.
7.如果你的答案和前面回复的答案思路相同通常不得分,但如果有改善可以得1分.
8.其他见开放区竞赛的总规则.(比如可以重复答题,但总得分最高是5分)
9. 如果作者自己修改了回复贴,则不再评分(6楼以后)
10.为防止大家把现在的方法通过复杂化来实现,从2007/10/1 起所有公式长度(含=)超过90个字符的答案不再评分.
  

EXCEL文件:

aLSyEYbV.zip (1.96 KB, 下载次数: 58)

2007-9-30 21:18 上传

点击文件名下载附件
[函数48]字符串末尾连续个数

 

QUOTE:

注意:为方便打分和以后看贴的连续性,请发帖者不要再修改自己回复的贴子, 如果答案有修改,请重新发新回复贴即可.
如果对评价以后的贴再修改,一律扣一分. (6楼以后执行)

QUOTE:

答题时间已结束.

[此贴子已经被作者于2008-3-19 22:25:19编辑过]

wddn

就来一个数组公式：

=MAX(IF(RIGHT(A8,ROW($1:$10))=REPT(RIGHT(A8),ROW($1:$10)),ROW($1:$10)))

QUOTE:

答案正确,评2分

[此贴子已经被willin2000于2007-9-30 23:15:33编辑过]

syz105729913

2LLKen5e.rar (3.53 KB, 下载次数: 12)

2007-9-30 17:48 上传

点击文件名下载附件
[函数48]字符串末尾连续个数

成功了，请版主检查

QUOTE:

当A1=

旺旺旺旺旺旺旺旺旺

或其他只有一个字符的字符串时错误.

结果错误. 扣回分数了. 不好意思. -willin2000

[此贴子已经被作者于2007-9-30 22:28:51编辑过]

yoka

9jQxNGAP.rar (2.09 KB, 下载次数: 11)

2007-9-30 17:52 上传

点击文件名下载附件
[函数48]字符串末尾连续个数

我也来个

改一下好象也可以的=LEN(A2)-MAX(IF(MID(A2,ROW(INDIRECT("1:"&LEN(A2))),1)<>RIGHT(A2),ROW(INDIRECT("1:"&LEN(A2))))

QUOTE:

由于3楼答案有错误,所以此答案不算重复,评2分 -willin2000

[此贴子已经被willin2000于2007-9-30 23:11:46编辑过]

山菊花

=COUNT(0/(RIGHT(A2,ROW($1:$1000))=REPT(RIGHT(A2),ROW($1:$1000))))

QUOTE:

答案正确,评2分

[此贴子已经被willin2000于2007-9-30 23:12:34编辑过]

红金鱼

=FREQUENCY(IF((LEFT(RIGHT(A2,ROW($1:$10)))=RIGHT(A2)),ROW($1:$10)),IF(LEFT(RIGHT(A2,ROW($1:$10)))<>RIGHT(A2),ROW($1:$10)))

复杂了点,但愿正确!受willin2000版本期正工竞赛的影响!

GAhEZhE7.rar (2.01 KB, 下载次数: 8)

2007-9-30 20:18 上传

点击文件名下载附件

QUOTE:

强调一下:此帖以下作者编辑修改过的贴子将不再评分

QUOTE:

当A1=旺旺旺旺旺旺旺旺旺

时结果错误. -willin2000

[此贴子已经被willin2000于2007-9-30 20:33:54编辑过]

胡剑0227

=LEN(A1)-LARGE(IF(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)<>RIGHT(A1,1),ROW(INDIRECT("1:"&LEN(A1))),-1),1)

数组公式。我是把最后一个不是末尾的数的位置找出来，然后用总的字符数减去这个字符的位置

QUOTE:

已经出现过了.不能评分.

一些解法虽然是自己想出来的,但只要前面已经有过类似的答案了,就不能得分,除非有改进.

[此贴子已经被willin2000于2007-9-30 20:55:10编辑过]

红金鱼

改了,但是越来越长了!

=IF((SUM(--(LEFT(RIGHT(A2,ROW(INDIRECT("1:"&LEN(A2)))))=RIGHT(A2))))=LEN(A2),SUM(--(LEFT(RIGHT(A2,ROW(INDIRECT("1:"&LEN(A2)))))=RIGHT(A2))),FREQUENCY(IF((LEFT(RIGHT(A2,ROW(INDIRECT("1:"&LEN(A2)))))=RIGHT(A2)),ROW(INDIRECT("1:"&LEN(A2)))),IF(LEFT(RIGHT(A2,ROW(INDIRECT("1:"&LEN(A2)))))<>RIGHT(A2),ROW(INDIRECT("1:"&LEN(A2))))))

eStKWyCD.rar (2.31 KB, 下载次数: 9)

2007-9-30 20:56 上传

点击文件名下载附件
[函数48]字符串末尾连续个数

QUOTE:

虽然正确,但绕了一些弯路,公式就太繁了,由于FREQUENCY没出现过, 评1分. -willin2000

[此贴子已经被willin2000于2007-9-30 23:21:17编辑过]

northwolves

=LEN(A2)-MAX((MID(A2,ROW(OFFSET($A$1,,,LEN(A2))),1)<>RIGHT(A2))*ROW(OFFSET($A$1,,,LEN(A2))))

=SUMPRODUCT(--(RIGHT(A2,ROW($1:$50))=REPT(RIGHT(A2),ROW($1:$50))))

QUOTE:

第一个公式和4楼相近, 差别在ROW 的用法(chenjun版主在图表用常用ROW(OFFSET,,)来产生引用.

第二个和5楼接近, 将COUNT改成了SUMPRODUCT ,但有所变化.

由于基本上采用了出现过的方法,原则上不评分. 但答了两个多有些变化的答案,综合考虑 评1分.

[此贴子已经被willin2000于2007-10-21 16:07:07编辑过]

胡剑0227

=MAX(IF(REPT(RIGHT(A1,1),ROW($1:$255))=RIGHT(A1,ROW($1:$255)),ROW($1:$255),))

数组公式。也是自己想的。

QUOTE:

胡剑0227出手太慢了噢, 2楼已经有了 -willin2000

[此贴子已经被willin2000于2007-9-30 21:23:07编辑过]