[讨论]状态栏(StatusBar)里的文字能不能改变字体的大小或颜色？

gonghao

状态栏(StatusBar)里的文字能不能改变字体的大小或颜色？

丸究阵引

参考

Public Declare Function GetSystemMetrics Lib "user32" (ByVal nIndex As Long) As Long
Public Declare Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Public Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Public Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long
Public Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long
Public Declare Function ReleaseDC Lib "user32" (ByVal hwnd As Long, ByVal hdc As Long) As Long
Public Declare Function SetTextColor Lib "gdi32" (ByVal hdc As Long, ByVal crColor As Long) As Long
Public Declare Function TextOut Lib "gdi32" Alias "TextOutA" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long, ByVal lpString As String, ByVal nCount As Long) As Long

Sub test()
     StatusBarX &HFF&
End Sub

'lngColor = 颜色 strMsg=显示文字
Public Sub StatusBarX(ByVal lngColor As Long, Optional strMsg As String) '2005-8-20修正
    
     Dim hEXCEL4 As Long
    
     Dim hDcExcel4 As Long, lngX As Long
   
     Const SM_CYCAPTION = 4
    
     Application.StatusBar = ""
    
     If strMsg = "" Then strMsg = "正在计算请稍等...."
    
     hEXCEL4 = EXCEL4(Application.Caption) '
    
     hDcExcel4 = GetDC(hEXCEL4) 'dc
    
     SetTextColor hDcExcel4, lngColor
    
     lngX = GetSystemMetrics(SM_CYCAPTION) '窗口标题的高度
    
     TextOut hDcExcel4, lngX, 2, strMsg, LenB(StrConv(strMsg, vbFromUnicode))
    
     ReleaseDC hEXCEL4, hDcExcel4
     
End Sub

Public Property Get EXCEL4(strCaption As String) As Long
    
     EXCEL4 = FindWindowEx(FindWindowA("XLMAIN", strCaption), ByVal 0&, "EXCEL4", vbNullString)

End Property

wangminbai

参见

http://club.excelhome.net/viewthread.php?tid=110512

丸究阵引

QUOTE:

以下是引用wangminbai在2007-8-6 7:07:33的发言：

参见

http://club.excelhome.net/viewthread.php?tid=110512

谢谢！正想做个类似的东东，送上门来了！哈哈！

不过在excel计算负担很重的情况下，闹这么大的动静很是担心！待偶有时间改改它.

gonghao

太强了，谢谢分享！

看来要学的东西真的太多了．

wenwu0318

学习学习再学习哈