样式问题

gemj

一篇文档设置了某些样式，但有时候有些现象挺奇怪的：

一是有些样式在它的基础上多出一种，或者几种，好象是它的衍生物，好比，本来一种样式叫choice，结果多出一种样式叫choice char 甚至choice char char，这种样式还不太好清除；

二是，一种样式本来设置就是左对齐，样式名称好比叫question，但某段文字，它的样式是“question+左对齐”，你选中这段文字，对其强行应用question，但它还是顽固地保持其本色！这是怎么回事呢？

我的感觉，为了尽可能避免这类情况的出现，在应该样式之前，最好不好全选文档，对整个文档设置某种格式，不知这种理解对不对？

konggs

呵呵，我也不太清楚。以前有会员讨论的，但还是不太清楚其中的原理。

c81

这个可能是早期Word的一个bug，和样式表有关，生成的文档可以在xp，03,及07中继续增加char，就是经过某种样式设置后它就多一个char,char1，有的人的文档中甚至多达10个以上（这个人对文档的样式不太敏感，呵呵）

解决办法

1.另存为新文档看看能不能摆脱这个内部病毒样的东西；

2.参考以下宏，是那个网站上的，可以将这些可恶的样式给全删除了。

[此贴子已经被作者于2007-6-2 20:38:19编辑过]

c81

网上最好的一个解决页面，请参阅：

http://www.windowsdevcenter.com/pub/a/windows/excerpt/wdhks_1/index.html?page=2

Sub DeleteCharCharStyles( )
Dim sty As Style
Dim i As Integer
Dim doc As Document
Dim sStyleName As String
Dim sStyleReName As String
Dim bCharCharFound As Boolean

Set doc = ActiveDocument
Do
    bCharCharFound = False
    For i = doc.Styles.Count To 1 Step -1
        Set sty = doc.Styles(i)
        sStyleName = sty.NameLocal
        If sStyleName Like "* Char*" Then
            bCharCharFound = True
            If sty.Type = wdStyleTypeCharacter Then
            On Error Resume Next
           '#############################################
           ' COMMENT OUT THE NEXT LINE IN WORD 2000 OR 97
           sty.LinkStyle = wdStyleNormal
           sty.Delete
           Err.Clear
        Else
           sStyleReName = Replace(sStyleName, " Char", "")
           On Error Resume Next
           sty.NameLocal = sStyleReName
           If Err.Number = 5173 Then
              Call SwapStyles(sty, doc.Styles(sStyleReName), doc)
              sty.Delete
              Err.Clear
           Else
             On Error GoTo ERR_HANDLER
           End If
         End If
         Exit For
      End If
      Set sty = Nothing
    Next i
  Loop While bCharCharFound = True
  Exit Sub
  ERR_HANDLER:
  MsgBox "An Error has occurred" & vbCr & _
          Err.Number & Chr(58) & Chr(32) & Err.Description, _
          vbExclamation
  End Sub
 
  Function SwapStyles(ByRef styFind As Style, _
                      ByRef styReplace As Style, _
                      ByRef doc As Document)
  With doc.Range.Find
       .ClearFormatting
       .Text = ""

       .Wrap = wdFindContinue
       .MatchCase = False
       .MatchWholeWord = False
       .MatchWildcards = False
       .MatchSoundsLike = False
       .MatchAllWordForms = False
       .Style = styFind
       .Replacement.ClearFormatting
       .Replacement.Style = styReplace
       .Replacement.Text = "^&"
       .Execute Replace:=wdReplaceAll
     End With
     End Function