[求助]word中如何按要求提取整段内容？

youusatst

如果要把当前文件中含“中国”两字的段落都提取到一个新文件，该如何操作？谢谢！

konggs

要格式吗？

konggs

不要格式的：

Sub 中国()
    Dim astring As String
    Dim arr, arr1, Restring As String
    Const ConstChina = "中国"
    '定义常量
   
        astring = ActiveDocument.Content '文档内容
        arr = Split(astring, Chr(13)) '分列为数组
        For Each arr1 In arr '每段中循环
            If InStr(arr1, ConstChina) > 0 Then
                Restring = Restring & arr1 & Chr(13)
            End If
        Next
        Dim doc As Document '添加新文档
        Set doc = Documents.Add
        doc.Content = Restring '内容添加到新文档
        doc.Paragraphs.Last.Range.Delete    '去掉最后一个回车
       
End Sub

[此贴子已经被作者于2007-2-24 12:19:30编辑过]

yuyvtul

不用VBA的方法应该有好多种，例如：
1.查找“中国”，替换：格式——段落，找一种特殊的比如首行缩进2.8字符，全部替换。
2.找到一个“中国”，右击，选择格式相似文本。复制，新文件中粘贴。
仅仅破坏了首行缩进值，其余格式不变。

守柔

QUOTE:

以下是引用konggs在2007-2-24 12:15:50的发言：

不要格式的：

Sub 中国()
    Dim astring As String
    Dim arr, arr1, Restring As String
    Const ConstChina = "中国"
    '定义常量
   
        astring = ActiveDocument.Content '文档内容
        arr = Split(astring, Chr(13)) '分列为数组
        For Each arr1 In arr '每段中循环
            If InStr(arr1, ConstChina) > 0 Then
                Restring = Restring & arr1 & Chr(13)
            End If
        Next
        Dim doc As Document '添加新文档
        Set doc = Documents.Add
        doc.Content = Restring '内容添加到新文档
        doc.Paragraphs.Last.Range.Delete    '去掉最后一个回车
       
End Sub

孔兄，我在你基础上做了一个，顺便分享一下数组常用函数。

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By SHOUROU@ExcelHome 2007-2-24 16:05:38
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0167^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Sub Example()
'本例旨在说明如何使用数组中的三个常用函数:Split,Filter,Join
    Dim myString As String, NewDoc As Document
    Dim myArray() As String, TempArray() As String
    Const myText As String = "敏捷"
    myString = ThisDocument.Content.Text    '取得文档内容
    myArray = VBA.Split(myString, Chr(13))    '以"段落"标记为分隔符取得数组
    TempArray = VBA.Filter(myArray, myText, True)    '返回一个包含指定文本的数组,即筛选后符合条件的数组
    Documents.Add.Content.Text = VBA.Join(TempArray, Chr(13)) '以"段落"标记为连接符将数组内容转换为文本字符串并写入空白文档
End Sub
'----------------------

konggs

老大利害[em17]。每次都忘了这几个现成的函数[em04].

菊石泽露

学习唯恐不及！

youusatst

谢谢楼上各位老师，我先操作，有问题再来请教。

linqiang0816

QUOTE:

以下是引用yuyvtul在2007-2-24 13:25:21的发言：
不用VBA的方法应该有好多种，例如：
1.查找“中国”，替换：格式——段落，找一种特殊的比如首行缩进2.8字符，全部替换。
2.找到一个“中国”，右击，选择格式相似文本。复制，新文件中粘贴。
仅仅破坏了首行缩进值，其余格式不变。

   为什么不首行缩进4个字符，这样就相当于正常的段落缩进样式了，在黏贴后也不需要再去调整缩进，更简单一点。

守柔

可以有多种使用查找与替换的方式，我拟了一种，供楼主参考：

请将“狐狸”更改为你需要查找的内容。

单击查找全部后，复制，到新文档中粘贴，注意，将最后一个内容段落移到新文档的开始（WORD中对于非连续文本，交换了首尾位置）