[求助]为何下面的代码在WORD 2K中只能转一次？

ssq1109

下面的代码是想将“[HL(”和“[HL)]”作首尾标记的文本中的“★”替换为“,”，在WORD 2003中没有问题，但因是在VB6中编的一小工具中用到的，因我发现如在VB6中引用WORD 2000的相关项后，编译得到的EXE文件中装有WORD 2000/XP/2003才都可用。故想在WORD 2000中也能用这段代码，但今天偶然发现这段代码在WORD 2K中只能转一次？即只对第一个符合条件的文本起作用，如后面出现符合条件的文本，都没有替换。

不知如何改动使之针对WORD 2000也能达到目的。

Sub HLreplace()
'
Selection.HomeKey unit:=wdStory
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
With Selection.Find
  Do
    .ClearFormatting
    .Text = "\[HL\(*\[HL\)\]"
    .MatchWildcards = True
    .Execute
  If InStr(1, .Parent.Text, "★") <> 0 Then
    .Execute findtext:="★", replacewith:=",", Replace:=wdReplaceAll
  End If
Loop Until .Found = False
End With
End Sub

K58S7dE2.rar (1.95 KB, 下载次数: 7)

2007-2-13 20:32 上传

点击文件名下载附件
[求助]为何下面的代码在WORD 2K中只能转一次？

守柔

请楼主在WORD2000测试一下：

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By SHOUROU@ExcelHome 2007-2-15 18:05:14
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0159^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Option Explicit

Sub Example()
    Dim myRange As Range, ThisRange As Range
    Application.ScreenUpdating = False
    Set myRange = ActiveDocument.Content
NF:     With myRange.Find
        .ClearFormatting
        .Text = "\[HL\(*\[HL\)\]"
        .MatchWildcards = True
        Do While .Execute
            '如不考虑格式,请直接使用REPLACE函数代替以下两句代码
            '            myRange.Text = VBA.Replace(myRange.Text, "★", ",")
            Set ThisRange = myRange
            ThisRange.Find.Execute findtext:="★", replacewith:=",", Replace:=wdReplaceAll
            myRange.SetRange myRange.End + 1, ActiveDocument.Content.End - 1
            GoTo NF
        Loop
    End With
    Application.ScreenUpdating = True
End Sub
'----------------------

ssq1109

谢谢守柔大侠！

此问题我已经用您上次给我复的帖子中的思路解决了（稍加改动即可）。此代码我明天试一下（那个老爷机现不在身边）。

ssq1109

高人！高招！

刚在WORD 2K上试了一下，非常好！对比我的解决办法更为简洁。

祝守版主、孔版主、如意版主、northwolves版主和C81版主新年愉快！

祝各位网友万事如意！

祝愿贵坛猪年人气更旺！