如何写一个这样的自动宏？

myurl

如何写一个这样的自动宏？

打开某个word文档，就给这个文档所有的页面自动加上页眉？

或者在退出时自动加上页眉。

有那位高手有的话，给小弟共享下。

[此贴子已经被作者于2007-2-14 14:50:29编辑过]

cxz008

QUOTE:

以下是引用myurl在2007-2-10 14:58:05的发言：

如何写一个这样的自动宏？

打开某个word文档，就给这个文档所有的页面自动加上页眉？

或者在退出时自动加上页眉。

有那位高手有的话，给小弟共享下。

打开时加上页眉？

那就需要先打开这个文档，编一段vba

仍然再打开，就可以加了。

myurl

不会，麻烦帮写下。

[em04]

sylun

楼主这种想法的实际意义是什么？自动宏放在哪？一定要用宏吗？如果一定要，必须用自动宏吗？

我不怎样了解宏，只是想知道楼主这种做法的必要性是什么。

守柔

QUOTE:

以下是引用sylun在2007-2-12 21:36:09的发言：

楼主这种想法的实际意义是什么？自动宏放在哪？一定要用宏吗？如果一定要，必须用自动宏吗？

我不怎样了解宏，只是想知道楼主这种做法的必要性是什么。

楼主的目的，我想是把他的所有目标文件自动加上页眉。

但楼主应该把问题细化，VBA不能泛泛而谈，必须针对对象而具体设计代码。

请问楼主：

你的页眉是怎么样的？你的目标文档中，有分节吗？有奇偶页不同吗？如果已有页眉了，怎么办？

等等，这些你必须写清楚，然后我可以给你做一个代码。

建议上传你的页眉实例和文档实例，以便我们分析。

myurl

[em04][em04]

没有想到版主这样复杂

本人做了个文档下载的网站http://www.jx97.com/，有很多文档，我都想加上网站名称的页眉，一个个加麻烦，以前的都是一个个加的[em09]，很是累的。所以想用宏来解决。

如果打开的文档没有页眉的话，那就加上我要加的页眉，如果有的话，就替换或在已有的页眉前面加都可以。

主要的文档是word文档，如果PPT文档能加也好。

[此贴子已经被作者于2007-2-14 14:51:31编辑过]

守柔

请参：

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By SHOUROU@ExcelHome 2007-2-15 7:11:13
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 0157^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Option Explicit
Private Sub Document_Open()
'为活动文档页眉中添加URL,请将其置于Normal.dot的THISDOCUMENT中
    Dim oSection As Section, myRange As Range, strTemp As String
    Const myURL As String = "http://www.jx97.com"
    On Error Resume Next
    With ActiveDocument
        For Each oSection In .Sections    '在节中循环
            '取得节主页眉区域的RANGE对象
            Set myRange = oSection.Headers(wdHeaderFooterPrimary).Range
            '如果该节没有设置页眉或者已设置页眉
            If Len(myRange) = 1 Then strTemp = "" Else strTemp = Chr(13)
            With myRange
                '判断是否已经设置了URL
                If VBA.InStr(.Text, myURL) = 0 Then
                    .SetRange .Start, .Start
                    .InsertBefore myURL & strTemp    '在页眉已有内容之前插入
                    '此处设置插入的URL字体与字号\段落对齐方式
                    .Font.Name = "Tahoma"
                    .Font.Size = 11
                    .Paragraphs(1).Alignment = wdAlignParagraphRight
                    '链接
                    .Hyperlinks.Add Anchor:=myRange, Address:=myURL
                End If
            End With
        Next
        .Save    '保存
    End With
End Sub
'----------------------

myurl

非常谢谢。。高手就是高手。。。