如何用宏修改目前打开的所有文件的模板

Amelia

请问如何用宏修改目前打开的所有文件所attach的模板？

用With ActiveDocument时可以使用.AttachedTemplate = "C:\Templates\Normal.dot"的功能，如果我想用With Documents,该怎么修改呢？

谢谢！

守柔

QUOTE:

以下是引用Amelia在2007-1-25 15:55:01的发言：

请问如何用宏修改目前打开的所有文件所attach的模板？

用With ActiveDocument时可以使用.AttachedTemplate = "C:\Templates\Normal.dot"的功能，如果我想用With Documents,该怎么修改呢？

谢谢！

希望楼主在表述问题时更清晰一点，有利于您可以一次得到问题的答案。比如，我们无法正确获悉你的目的， 是修改模板中的什么，修改代码吗？

Sub Example()
    Dim oDoc As Document
    For Each oDoc In Documents
        Debug.Print oDoc.AttachedTemplate.FullName
    Next
End Sub

Amelia

我用的是英文的word，有的术语不知道如何用中文表达，真的很抱歉。我有一些老的文件，当时attach的是自己定义的模板，现在那个模板不需要早就删掉了已经不存在，打开时word自动找那个老的模板速度特别慢，我想都改成word自带的normal.dot。我试过，只要到templates and add-in里把template替换掉，保存再打开速度就正常了。

但是，现在我有新问题了，我有近千个这些文件，怎么才能不用一次一次到templates and add-in里去替换啊。

比如说：我试了一下用

With ActiveDocument

.AttachedTemplate = "C:\Templates\Normal.dot

可以改变当前打开的一个文档的模板，怎么样可以改变所有当前打开的文档的模板呢。例如用With Documents，但是后面不知道怎么写。。。。

这样说不知道还算清楚，抱歉啊，表达能力有点差，对不起大家了。。。

守柔

试一下这个：

'* ＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋＋
'* Created By Zhjp@ExcelHome 2007-1-26 12:16:35
'仅测试于System: Windows NT Word: 11.0 Language: 2052
'№ 00067^The Code CopyIn [ThisDocument-ThisDocument]^'
'* －－－－－－－－－－－－－－－－－－－－－－－－－－－－－

Option Explicit

Sub Example2()    '此代码功能为列出指定文件夹中所有选取的WORD文件全路径名
    Dim MyDialog As FileDialog, vrtSelectedItem As Variant
    Dim myDoc As Document
    On Error Resume Next    '忽略错误
    '定义一个文件夹选取对话框
    Set MyDialog = Application.FileDialog(msoFileDialogFilePicker)
    With MyDialog
        .Filters.Clear    '清除所有文件筛选器中的项目
        .Filters.Add "所有 WORD 文件", "*.doc", 1    '增加筛选器的项目为所有WORD文件
        .AllowMultiSelect = True    '允许多项选择
        If .Show = -1 Then    '确定
            For Each vrtSelectedItem In .SelectedItems    '在所有选取项目中循环
                Set myDoc = Word.Documents.Open(FileName:=vrtSelectedItem, Visible:=False)
                If myDoc.AttachedTemplate.FullName <> Application.NormalTemplate.FullName Then
                    myDoc.AttachedTemplate = Application.NormalTemplate.FullName
                    myDoc.Close True
                Else
                    myDoc.Close False
                End If
            Next
        End If
    End With
End Sub
'----------------------

Amelia

运行时让我要选文件，不知道什么意思。。。（不好意思，我很弱的）

我找了老外写的一个，很简单，试了一下满好用的，但是只能执行当前目录下的文件，不能遍历目录下子文件夹的文件，可以修改吗？谢谢！

Sub ChangeTemplates()
    Dim strDocPath As String
    Dim strTemplateB As String
    Dim strCurDoc As String
    Dim docCurDoc As Document

     strDocPath = "C:\Documents and Settings\administrator\Desktop\folder\"
    strTemplateB = "D:\Templates\normal.dot"

     strCurDoc = Dir(strDocPath & "*.doc")

    Do While strCurDoc <> ""
        Set docCurDoc = Documents.Open(FileName:=strDocPath & strCurDoc)
        docCurDoc.AttachedTemplate = strTemplateB
         docCurDoc.Close wdSaveChanges
         strCurDoc = Dir
    Loop
    MsgBox "Finished"
    End Sub

Amelia

哈哈，我终于搞定了。 最后用了filesearch的功能。