求助！ 如何让光标定位在某特定词语后面的表格中

xxcc

求助！ 如何在表格中让光标定到在某特定词语后面的表格中，并填写相应词语。谢谢！！！如定位到施工负责人后面的表格中，并填写“马良”，

施工负责人

而且表格中还有此词语又如何继续填写 　

[此贴子已经被作者于2006-12-13 10:11:28编辑过]

守柔

QUOTE:

以下是引用xxcc在2006-12-13 10:09:15的发言：
求助！ 如何在表格中让光标定到在某特定词语后面的表格中，并填写相应词语。谢谢！！！如定位到施工负责人后面的表格中，并填写“马良”，

施工负责人

而且表格中还有此词语又如何继续填写 　

想问几个问题：

你的特定词语是文档中唯一的吗？它位于表格中吗？你的文档中的表格有多个类似的吗？如果是，每个后面的单元格（是单元格还是表格）中填写“马良”吗？

你的目的是填写而非光标定位吧。

请楼主回答以上问题后，我们再回复您。

xxcc

特定的词语，在文档中多次出现；在表格中；我文档中表格是同一个模板，是表格，都填马良；我的目的是填写，请斑竹帮忙。

守柔

我没有很实际地考量这个问题，请参考：

Option Explicit

Sub Example()
    Dim myRange As Range, myString As String, myCell As Cell
    Dim i As Table
    Application.ScreenUpdating = False
    myString = "施工负责人"
    For Each i In ActiveDocument.Tables
        Set myRange = i.Range
        With myRange.Find
            .ClearFormatting
            .Text = myString
            Do While .Execute = True
                Set myCell = myRange.Cells(1).Next
                myCell.Range.Text = "马良"
                GoTo NF
            Loop
        End With
NF:    Next
    Application.ScreenUpdating = True
End Sub

xxcc

谢谢，已经搞定！再深问一步，如何在此段代码中增加判断语句，施工负责人"后面的表格是否含有斜线，如有则不增加“马良”，继续向下搜索

守柔

QUOTE:

以下是引用xxcc在2006-12-14 8:42:34的发言：

谢谢，已经搞定！再深问一步，如何在此段代码中增加判断语句，施工负责人"后面的表格是否含有斜线，如有则不增加“马良”，继续向下搜索

请参考：

Option Explicit

Sub Example()
    Dim myRange As Range, myString As String, myCell As Cell
    Dim i As Table
    Application.ScreenUpdating = False
    myString = "施工负责人"
    For Each i In ActiveDocument.Tables
        Set myRange = i.Range
        With myRange.Find
            .ClearFormatting
            .Text = myString
            Do While .Execute = True
                Set myCell = myRange.Cells(1).Next
                If myCell.Borders(wdBorderDiagonalDown) = False And myCell.Borders(wdBorderDiagonalUp) = False Then
                    myCell.Range.Text = "马良"
                End If
                GoTo NF
            Loop
        End With
NF:         Next
    Application.ScreenUpdating = True
End Sub

xxcc

谢谢！！