[求助]在VB中怎样将处理了的*.TXT文件另存为*.DOC文件？

ssq1109

不好意思，与本坛有点不符，但在专门的VB中也得不到解决。到此会有好运。

为在VB中操作WORD，先作适当引用（略），再：

Dim wdApp As Word.Application
Dim aDoc As Document
Set wdApp = New Word.Application

 '打开窗体上TextBox中的文本（此文本是一个文本文件）
Set aDoc = wdApp.Documents.Open(Filename:=Form1.Filename.Text)
wdApp.Visible = True       '设置Word对象可见

……      '省略的是主程序，多为文本替换代码

'用下列语句可将文件存在原文件目录下：
aDoc.SaveAs aDoc.Path & "\" & aDoc.Name & ".doc"   '将文档另存为
aDoc.Close      '关闭文档
wdApp.Quit      '结束Word对象
Set aDoc = Nothing
Set wdApp = Nothing     '释放Word对象

但仍有2个问题：
1．若源文件是文本文件，存的*.DOC还是文本文件格式，怎样让其成为真正的WORD文档格式：
2．所存文件名不合要求，如源文件为：ABC.TXT，存的结果为：ABC.TXT.DOC，而我希望为ABC.DOC（即只取源文件的主名＋.DOC）

守柔

先试一下这个再说：

 With aDoc
        .SaveAs .Path & "\" & .ActiveWindow.Caption & ".doc"    
        .Close      
        Set aDoc = Nothing
    End With

ssq1109

非常谢谢守柔大侠！

我刚试了一下，好像和1楼的是等效的。

我看VBA帮助文件后将1楼的一句改为：

aDoc.SaveAs aDoc.Path & "\" & aDoc.Name & ".doc", FileFormat:=wdFormatDocument '文件另存为DOC
1楼所说的第1个问题（即文件格式）解决了，但第2个问题依旧。

konggs

ssq1109兄利用mid+len函数不行吗？

aDoc.SaveAs aDoc.Path & "\" & mid(aDoc.Name,1,len(adoc.name)-4)) & ".doc", FileFormat:=wdFormatDocument

????

ssq1109

谢谢孔版主！

这个方法我也想过，因程序要读方正早期的一种无扩展名的文本文件，用此法就不行了。

我想了一下，第2个问题解决不了也无大碍。只是看着有点别扭。

konggs

ssq1109兄。不能用if吗？

判断最后四个字符是否是.txt是的话去掉；否则，留着。不行吗？

ssq1109

好主意，谢谢孔兄！

ssq1109

在孔兄的提示下，改写了，能PASS，但总觉2、3、4部分可合并。

If Right(aDoc.Name, 4) = ".doc" Then
  '为避免将源DOC文档覆盖，此类文件单独处理，在其主名后加"_Z.DOC"
   aDoc.SaveAs aDoc.Path & "\" & Mid(aDoc.Name, 1, Len(aDoc.Name) - 4) & "_Z.DOC", FileFormat:=wdFormatDocument

ElseIf Right(aDoc.Name, 4) = ".fbd" Then
   aDoc.SaveAs aDoc.Path & "\" & Mid(aDoc.Name, 1, Len(aDoc.Name) - 4) & ".DOC", FileFormat:=wdFormatDocument

ElseIf Right(aDoc.Name, 4) = ".txt" Then
   aDoc.SaveAs aDoc.Path & "\" & Mid(aDoc.Name, 1, Len(aDoc.Name) - 4) & ".DOC", FileFormat:=wdFormatDocument

ElseIf Right(aDoc.Name, 4) = ".rtf" Then
   aDoc.SaveAs aDoc.Path & "\" & Mid(aDoc.Name, 1, Len(aDoc.Name) - 4) & ".DOC", FileFormat:=wdFormatDocument

Else
   aDoc.SaveAs aDoc.Path & "\" & aDoc.Name & ".DOC", FileFormat:=wdFormatDocument
    
End If

ssq1109

8楼的代码看似可以，实际还可能有2个问题，望各位老大斧正。

1．如果和文件的扩展名都为小写字母，则无问题，但为大写字母或大小定混用就惨了。

2．第2、3、4部分似乎重复，应可合并，对吗？

konggs

1.用Option compare Text

例如：

Option Explicit
Option Compare Text
Sub aaa3()
Dim a, b
a = ".txt": b = ".TXT"
If a = b Then
    MsgBox "="
End If
End Sub

2.为什么不用or?

ifelse Right(aDoc.Name, 4) = ".fbd"  or Right(aDoc.Name, 4) = ".txt" or Right(aDoc.Name, 4) = ".rtf" then