请什么函数能弹出一个文件选择的窗口

reftin

就象文件->打开->浏览那种

然后返回一个带路径的文件名

3q

hiyou

Sub test()
Set dlgx = Application.FileDialog(msoFileDialogOpen)  '创建filedialog对象，这是你要的
dlgx.InitialFileName = "c:\"    '指定路径，文件名和过滤字符也在此指定，如C:\*.TXT

If dlgx.Show = -1 Then    'SHOW方法弹出选择窗口，如果用户选了文件，会返回-1，放弃是0
  'selecteditems是个集合，用户多选要用FOR EACH遍历，我不演示了，一般的应用只选第一个
  MsgBox "你选中了" & dlgx.SelectedItems(1)
End If

End Sub

[此贴子已经被作者于2006-6-29 8:33:02编辑过]

可乐虫

Sub dd()
'**********************************CommonDialog显示打开框**********************************
'ShowOpen 显示“打开”对话框
'ShowSave 显示“另存为”对话框
'ShowColor 显示“颜色”对话框
'ShowFont 显示“字体”对话框
'ShowPrinter 显示“打印”或“打印选项”对话框
'ShowHelp 调用 Windows 帮助引擎
    Dim GetFileName As String
    Dim Dia As Object
    Set Dia = CreateObject("MSComDlg.CommonDialog")
    Dia.Filter = "文本文件|*.txt|Word文件|*.doc|Excel文件|*.xls"
    Dia.ShowOpen
    GetFileName = Dia.Filename
    MsgBox GetFileName
End Sub
Sub ddd()
'**********************************CommonDialog显示另存为框**********************************
    Dim GetFileName As String
    Dim Dia As Object
    Set Dia = CreateObject("MSComDlg.CommonDialog")
    Dia.Filter = "文本文件|*.txt|Word文件|*.doc|Excel文件|*.xls"
    Dia.ShowSave
    GetFileName = Dia.Filename
    MsgBox GetFileName
End Sub

hiyou

MSCOMDLG.CommonDialog是常用的控件，不过使用中要注意的是，这个东西是“外带控件”，它不保证与OFFICE一起注册

这个控件对象在我的印象中是随VS开发套件（象VS98中的VC6、VB6，还有VB5、VF5之类）一起发布的，所以常常在用户机上都有，但它的普及性还是不如FSO、ADO这些对象），写程序的时候，为了代码的健壮性，我个人的建议，尽量用回“本程序环境的对象”

不过，假如是在用OFFICE97的话（这也有可能，比如某些生产系统，办公系统，它因配置要求和安全要求安装OFF97），我上面的话就要作废，那时APPLICATION好象是没有FileDialog的，倒不如去用系统的MSCOMDLG.Commondialog了

可乐虫

感谢楼上的建议！！！。

由于我是搞VB的，所以比较注重代码的通用性,因为CommonDialog在VB里就是一个控件，实现起来很简单，所以我在研究VBA的时候跟VB通用了，呵呵！！！

爱歌学习

哦，那这个呢？

Sub GetOpenFilenamee()
    'filefilter1 = "microsoft office excel files (*.xls),*.xls"
    filefilter1 = "所有文件,*.*"
    fn = Application.GetOpenFilename(filefilter1, , "请选文件", , MultiSelect:=True)
    If Not IsArray(fn) Then Exit Sub
    For Each f In fn
        MsgBox f
    Next
End Sub

可乐虫

强，VBA居然自带的，

hiyou

好象APPLICTION的GETOPENFILE方法看起来直观一些，不过，我查资料没有改变目录的属性，它似乎是EXCEL的当前目录，这样的话不太方便，比如说一开始想给用户打开某个目录的话...

taller

Chdir "c:\temp"

可乐虫

呵呵 Chdir