食谱格式转化

沧海一栗666

这个搞死人，把合并单元格取消了，才搞出来

1. =LET(
   
2.     DATA,
   
3.     A5:E213,
   
4.     T,
   
5.     SCAN(, A5:A213, LAMBDA(X, Y, IF(IFERROR(FIND("星期", Y), 0), Y, X))),
   
6.     TT,
   
7.     IF(A5:A213 <> "", T, ""),
   
8.     TX,
   
9.     UNIQUE(T),
   
10.     FZ,
    
11.     LAMBDA(
    
12.         Z,
    
13.         LET(
    
14.             ARR,
    
15.             DROP(FILTER(DATA, TT = Z), 2),
    
16.             BRR,
    
17.             GROUPBY(
    
18.                 CHOOSECOLS(ARR, 1, 2),
    
19.                 REGEXP(CHOOSECOLS(ARR, 3), "^[^(（[{]+") & "(" &
    
20.                     CHOOSECOLS(ARR, 5) & "g)",
    
21.                 LAMBDA(x, ARRAYTOTEXT(x)),
    
22.                 0,
    
23.                 0
    
24.             ),
    
25.             CRR,
    
26.             IFERROR(VSTACK(Z, {"用餐分类","菜名","材料"}, BRR), ""),
    
27.             CRR
    
28.         )
    
29.     ),
    
30.     DROP(REDUCE("", TX, LAMBDA(A, B, VSTACK(A, FZ(B)))), 1)
    
31. )

复制代码

yangqianming

沧海一栗666 发表于 2026-1-14 18:02
这个搞死人，把合并单元格取消了，才搞出来

的确难搞，我都搞迷糊了就是弄不好！

yangqianming

你是那块小饼干 发表于 2026-1-14 17:14

你真厉害，感觉应该没有什么问题能难得住你！

mykitami

感觉也可以搞，只是结果中的星期天与星期一的合并单元格公式无法解决

沧海一栗666

mykitami 发表于 2026-1-14 22:20
感觉也可以搞，只是结果中的星期天与星期一的合并单元格公式无法解决

DROP(REDUCE("", TX, LAMBDA(A, B, VSTACK({“”，A，“”}, FZ(B)))), 1)，只能模拟到中间单元格，合并单元格只能VBA了吧

huihuang6669

1. =LET(f,LAMBDA(f,x,LET(t,TAKE(x,1,1),n,IFNA(XMATCH("星期*",DROP(x,2),2)-1,ROWS(x)-2),a,MAP(OFFSET(t,2,,n,2),LAMBDA(m,IF(m="",LOOKUP("々",OFFSET(t,,COLUMN(m)-1):m),m))),c,REGEXP(OFFSET(t,2,2,n),"^\p{sc:Han}+|$")&"（"&BYROW(OFFSET(t,2,3,n,4),SUM)&"）",d,VSTACK(OFFSET(t,,,2,3)&"",GROUPBY(a,c,LAMBDA(g,TEXTJOIN("，",1,g)),,0,-1,c<>"（0）")),IF(ROWS(x)=n+2,d,VSTACK(d,f(f,DROP(x,n+2)))))),f(f,原食谱!A5:A208))

复制代码

yangqianming

huihuang6669 发表于 2026-1-15 08:13

我用的wps显示有点儿问题，

huihuang6669

yangqianming 发表于 2026-1-15 12:37
我用的wps显示有点儿问题，

我也用的WPS，没问题啊

秃头发师

=LET(arr,SCAN(,原食谱!A5:A231,LAMBDA(x,y,IF(y<>"",y,x))),
     brr,SCAN(,原食谱!B5:B231,LAMBDA(x,y,IF(AND(y="",OFFSET(y,,1)=""),"",IF(y<>"",y,x)))),
     crr,REGEXREPLACE(原食谱!C5:C231,"\K(（|【|［).+",""),
     drr,IF(ISNUMBER(原食谱!E5:E231),crr&"（"&原食谱!E5:E231&"g）","")&IF(原食谱!E5:E231="小学","材料",""),
     err,SCAN(,arr,LAMBDA(x_,y_,IF(REGEXTEST(y_,"星期"),y_,x_))),
     frr,MATCH(err,{"星期天";"星期一";"星期二";"星期三";"星期四";"星期五";"星期六"},0),
     grr,MATCH(LEFT(arr,1),{"星";"用";"早";"午";"晚"},0),
     hrr,GROUPBY(HSTACK(frr,grr,err,arr,brr&""),drr,ARRAYTOTEXT,0,0,,NOT((原食谱!A5:A231="")*(原食谱!C5:C231=""))),
     DROP(hrr,,3))

mykitami

M365
=LET(aa,原食谱!A5:A999,cc,原食谱!C5:C999,d,SCAN(,aa,LAMBDA(x,y,IF(LEFT(y,2)="星期",y,x))),c,SCAN("",aa,LAMBDA(x,y,IF(RIGHT(y)="餐",y,x))),m,SCAN("",原食谱!B5:B999,LAMBDA(x,y,IF((y<>"菜名")*(y<>""),y,x))),f,FILTER(HSTACK(d,c,m,cc,原食谱!E5:E999),(cc<>"")*(cc<>"材料")),cl,REGEXEXTRACT(INDEX(f,,4),"\pL+"),ck,cl&"（"&TAKE(f,,-1)&"g）",w,TAKE(f,,1),REDUCE(原食谱!A1,UNIQUE(w),LAMBDA(x,y,LET(q,FILTER(HSTACK(INDEX(f,,2),INDEX(f,,3),ck),w=y),IFNA(VSTACK(x,VSTACK(y,{"用餐分类","菜名","材料"},GROUPBY(TAKE(q,,2),TAKE(q,,-1),ARRAYTOTEXT,0,0,-1))),"")))))