求助老师写一下公式

三票

求助老师写一下公式

那天的月亮

=LET(x,TAKE(TOROW(TEXT(D3:J3,"0;0!z")*1,3),,4),HSTACK(x,MIN(x)))

石头怪

模拟结果 ，跟需求，是不是不一致

三票

石头怪 发表于 2025-12-10 10:36
模拟结果 ，跟需求，是不是不一致

改了，输入错误，老师看一下

hxj119

1. =INDEX(FILTER(D3:J3/1,IFERROR(D3:J3/1,0)>0),{1,2,3,4})

复制代码

1. =MIN(T3:W3)

复制代码

cnppp

=TAKE(LET( b, IF(IFERROR(--D3:J11, 0)=0, 99, IFERROR(--D3:J11, 0)), MAKEARRAY(ROWS(b), COLUMNS(b),LAMBDA(r,c,SMALL(INDEX(b, r, 0), c)))),,4)

良良

L3
数组：=INDEX($D3:$J3,SMALL(IF($D3:$J3<>"",COLUMN($A:$G)),COLUMN(A1)))
非数组：=MOD(AGGREGATE(15,6,(COLUMN($A:$G)/1%+$D3:$J3)/($D3:$J3<>""),COLUMN(A1)),100)
Q3
数组：=MIN(IF(D3:J3<>"",--D3:J3))
非数组：=AGGREGATE(15,6,D3:J3/(D3:J3<>""),1)

loirol

=MIN(IF(IFERROR(--D3:J3,9^9)>0,IFERROR(--D3:J3,9^9),9^9))

老版本三键

theking_wsz

.....................................................................

fgq5910

=MAKEARRAY(ROWS(D3:J11), 4, LAMBDA(r,c,
    LET(
        rowData, INDEX(D3:J11, r, 0),
        filtered, FILTER(rowData, rowData<>""),
        IF(c <= COLUMNS(filtered), INDEX(filtered, c), "")
    )
))