怎么样用PIVOTBY一步实现想要的结果

cheng660900

具体见例子

谢谢！

cnppp

F5=LET( a, FILTER(数据源!D4:K55, 数据源!B4:B55=F4), b, CHOOSECOLS(a,1,2,8,6,7), TOCOL(BYCOL(b, LAMBDA(col, LET( c, INDEX(col, 1), IF(ISNUMBER(c) * ISNUMBER(0+c),SUM(col), TEXTJOIN("、", TRUE, col)))))))

G5=LET( a, FILTER(数据源!D4:K55, 数据源!B4:B55=B4),TOCOL(BYCOL(CHOOSECOLS(a,1,2,8,6,7), LAMBDA(col, SUM(col)))))

H5=LET( m,数据源!D4:K55,  n,数据源!B4:B55,  a, CHOOSECOLS(FILTER(m, (n>=202501)*(n<=B4)), 1,2,8),  b, CHOOSECOLS(FILTER(m, n=B4), 6,7),VSTACK(TOCOL(BYCOL(a, LAMBDA(x, SUM(x)))), TOCOL(BYCOL(b, LAMBDA(x, SUM(x))))))

I5=LET( m,数据源!D4:K55, n,数据源!B4:B55, a, CHOOSECOLS(FILTER(m, (n>=202401)*(n<=B5)), 1,2,8), b, CHOOSECOLS(FILTER(m, n=B5), 6,7), VSTACK(TOCOL(BYCOL(a, LAMBDA(x, SUM(x)))), TOCOL(BYCOL(b, LAMBDA(x, SUM(x))))))

hxj119

在数据表中间有这些数据，并且没有说明是那一年的预算，显然不合适，这就是坑呀！

cheng660900

谢谢 我先试试 谢谢大神

rym9401

没有详细核对，是否完全正确。楼主如果需要就回复我。

cnppp

前面2楼的公式是包含全部板块的计算，下面的公式添加计算板块为固废的条件：
F5=TOCOL(CHOOSECOLS(FILTER(数据源!D4:K55, (数据源!B4:B55=F4)*(数据源!C4:C55=B3)),{1,2,8,6,7}))

G5=TOCOL(CHOOSECOLS(FILTER(数据源!D4:K55, (数据源!B4:B55=B4)*(数据源!C4:C55=B3)),{1,2,8,6,7}))

H5=LET( d,数据源!D4:K55, 月份,数据源!B4:B55, 板块,数据源!C4:C55, a, CHOOSECOLS(FILTER(d, (月份>=202501)*(月份<=B4)*(板块=B3)), 1,2,8), b, CHOOSECOLS(FILTER(d, (月份=B4)*(板块=B3)), 6,7), VSTACK(TOCOL(BYCOL(a, LAMBDA(x, SUM(x)))), TOCOL(BYCOL(b, LAMBDA(x, SUM(x))))))

I5=LET( d,数据源!D4:K55,月份,数据源!B4:B55,板块,数据源!C4:C55,a, CHOOSECOLS(FILTER(d, (月份>=202401)*(月份<=B5)*(板块=B3)), 1,2,8), b, CHOOSECOLS(FILTER(d, (月份=B5)*(板块=B3)), 6,7),VSTACK(TOCOL(BYCOL(a, LAMBDA(x, SUM(x)))),TOCOL(BYCOL(b, LAMBDA(x, SUM(x))))))

渡渡orz

怎么样用PIVOTBY一步实现想要的结果.rar (154.13 KB, 下载次数: 3)

2025-12-8 16:22 上传

点击文件名下载附件

透视，供参考。

你是那块小饼干

有文本 PI没搞出来
=INDEX(数据源!$D$4:$K$55,MATCH($F$4&$B$3,数据源!$B$4:$B$55&数据源!$C$4:$C$55,0),MATCH(抓取结果!$D5,数据源!$D$3:$K$3,0))

你是那块小饼干

1. =SUMIFS(OFFSET(数据源!$A$3,1,MATCH(抓取结果!$D5,数据源!$B$3:$K$3,0),COUNTA(数据源!B:B)-1),数据源!$C$4:$C$55,抓取结果!$B$3,数据源!$B$4:$B$55,抓取结果!$B$4)

复制代码

你是那块小饼干

1. =SUMIFS(OFFSET(数据源!$A$3,1,MATCH(抓取结果!$D5,数据源!$B$3:$K$3,0),COUNTA(数据源!B:B)-1),数据源!$C$4:$C$55,抓取结果!$B$3,数据源!$B$4:$B$55,"<="&抓取结果!$B$4,数据源!$B$4:$B$55,">="&VALUE(LEFT(B4,4)&"01"))

复制代码