利用函数判断身份证格式对否

南区人 · 发表于 2025-3-31 17:12

例如身份证不等于18位，或者不符合身份证格式，设置找出函数。谢谢大神

A九月 · 发表于 2025-3-31 18:06

18位好判断，一个LEN函数就好了。格式貌似不好搞。

wyslw2004 · 发表于 2025-3-31 18:13

=IF(LEN(A1)<>18, "位数不对", IF(CHOOSE(MOD(SUM(MID(A1, ROW(INDIRECT("1:17")), 1)*{7;9;10;5;8;4;2;1;6;3;7;9;10;5;8;4;2}), 11)+1, 1, 0, "X", 9, 8, 7, 6, 5, 4, 3, 2)=IF(ISNUMBER(RIGHT(A1, 1)*1), RIGHT(A1, 1)*1, "X"), "正确", "错误"))

无关岁月 · 发表于 2025-3-31 18:17

=MID("10x98765432",MOD(SUM(MID(C5,SEQUENCE(17),1)*2^(18-SEQUENCE(17))),11)+1,1)=UPPER(RIGHT(C5))

复制代码

mengrs · 发表于 2025-3-31 18:41

本帖最后由 mengrs 于 2025-3-31 18:43 编辑

低版本：
=IFERROR(IF(MID("10X98765432",MOD(SUMPRODUCT(MID(A1,ROW($1:$17),1)*2^(18-ROW($1:$17))),11)+1,1)=UPPER(MID(A1,18,1)),"对","错"),"")

静听溪流 · 发表于 2025-3-31 20:05

xtmyd5156 · 发表于 2025-4-1 15:38

无关岁月发表于 2025-3-31 18:17

无佬威武，手到病除

pjiang · 发表于 2025-4-1 16:28

=IF(LEN(F4)<>18,"非二代身份证",IF(MID("10X98765432",(MOD(SUMPRODUCT(MID(F4,ROW(INDIRECT("1:17")),1)*{7;9;10;5;8;4;2;1;6;3;7;9;10;5;8;4;2}),11)+1),1)=RIGHT(F4),"对","错"))

waternew · 发表于 2025-4-1 16:33

无关岁月发表于 2025-3-31 18:17

老师，能给说一下原理吗？没看明白其中的逻辑

用户名		自动登录	找回密码
密码			免费注册

[求助] 利用函数判断身份证格式对否

评分