余数分组问题

pswxm2013 · 发表于 2025-1-1 11:46

如何实现这样的分组效果：按人数均分五组，多余的人数分至前面的组，每组增1人。请求高手帮助。谢谢！

pgp5866 · 发表于 2025-1-1 11:58

=BYCOL(WRAPROWS(SEQUENCE(A2,,1,0),5,0),SUM)

复制代码

zwzc · 发表于 2025-1-1 12:08

本帖最后由 zwzc 于 2025-1-1 12:19 编辑

B2=IF(MOD(SUM($A2*2,-$A2:A2),7-COLUMN()),INT(SUM($A2*2,-$A2:A2)/(7-COLUMN()))+1,INT(SUM($A2*2,-$A2:A2)/(7-COLUMN())))

leepoison · 发表于 2025-1-1 12:12

本帖最后由 leepoison 于 2024-12-31 16:29 编辑

=BYCOL(WRAPROWS(REPTARRAY(1,A2),5,0),SUM)

复制代码

=BYCOL(WRAPROWS(IF(SEQUENCE(,A2),1),5,0),SUM)

复制代码

良良 · 发表于 2025-1-1 12:19

B2=IF(INT(($A2*2-SUM($A2:A2))/(6-COLUMN(A1)))=($A2*2-SUM($A2:A2))/(6-COLUMN(A1)),($A2*2-SUM($A2:A2))/(6-COLUMN(A1)),ROUNDUP($A2/5,0))，右拉、下拉。

cnmlgb9998 · 发表于 2025-1-1 12:48

xtmyd5156 · 发表于 2025-1-1 13:26

你是那块小饼干 · 发表于 2025-1-1 14:34

=LET(T,COUNTA($B$1:$F$1),_T,ROUNDDOWN(A2/T,0),_X,MOD(A2,T),BYCOL(IFNA(VSTACK(EXPAND(_T,,T,_T),IF(_X=0,0,EXPAND(1,,_X,1))),0),SUM))

复制代码

quqiyuan · 发表于 2025-1-1 15:28

=INT($A2/5)+N(MOD($A2,5)>=COLUMN(A$1))

mykitami · 发表于 2025-1-1 15:47

=TEXTSPLIT(REPT(INT(A2/5)&" ",5)," ",,1)+IF(SEQUENCE(,5)>A2-INT(A2/5)*5,0,1)

		自动登录	找回密码
密码			免费注册

[已解决] 余数分组问题

评分

评分

评分

评分

评分

评分

评分

评分

评分