多sheet根据条件合并计算

chuchuliwu · 发表于 2024-12-19 10:56

本帖最后由 chuchuliwu 于 2024-12-19 10:54 编辑

问题：
为了让汇总表能根据方案编号进行计算汇总，目前C2单元格使用了多个sumif进行合计。（各表编号顺序不一致）
但是随着部门的增多，这个公式使用起来就没那么方便了，请教大神们，给出更优解。

袁勇 · 发表于 2024-12-19 11:08

=SUM(SUMIF(INDIRECT({"财务部","生产部","销售部","行政部"}&"!b:b"),B2,INDIRECT({"财务部","生产部","销售部","行政部"}&"!c:c")))

=SUM(SUMIF(INDIRECT({"财务部","生产部","销售部","行政部"}&"!c[-1]",),B2,INDIRECT({"财务部","生产部","销售部","行政部"}&"!c",)))

lu553178681 · 发表于 2024-12-19 11:12

=+SUM(SUMIFS(INDIRECT(SHEETSNAME(,,1)&"!C:C"),INDIRECT(SHEETSNAME(,,1)&"!B:B"),B2))

复制代码

hugeinfo · 发表于 2024-12-19 11:14

=LET(a,DROP(REDUCE("",SHEETSNAME(,1,1)&"!B2:C100",LAMBDA(x,y,VSTACK(x,VSTACK(INDIRECT(y))))),1),SUM((TAKE(a,,1)=B2)*TAKE(a,,-1)))

chuchuliwu · 发表于 2024-12-19 14:21

lu553178681 发表于 2024-12-19 11:12

感谢大神，一下子看懂了这个公式。
要是我有个新要求，本月计算的时候，财务部的不汇总进去，但是sheet还是得留着，有办法解决不？

乔124578 · 发表于 2024-12-19 14:58

chuchuliwu 发表于 2024-12-19 14:21
感谢大神，一下子看懂了这个公式。
要是我有个新要求，本月计算的时候，财务部的不汇总进去，但是sheet ...

那就把财务的数据清零就行了

lu553178681 · 发表于 2024-12-19 15:27

chuchuliwu 发表于 2024-12-19 14:21
感谢大神，一下子看懂了这个公式。
要是我有个新要求，本月计算的时候，财务部的不汇总进去，但是sheet ...

用DROP的三参控制吧，计算就设为0，不计算就设为1

=+LET(X,DROP(SHEETSNAME(,,1),,1),SUM(SUMIFS(INDIRECT(X&"!C:C"),INDIRECT(X&"!B:B"),B2)))

复制代码

thy645 · 发表于 2024-12-19 16:09

你是那块小饼干 · 发表于 2024-12-19 16:25

=SUM(IF(VSTACK(财务部:行政部!$B$2:$B$200)=B2,VSTACK(财务部:行政部!$C$2:$C$200),""))

复制代码

=SUMPRODUCT((VSTACK(财务部:行政部!$B$2:$B$200)=B2)*VSTACK(财务部:行政部!$C$2:$C$200))

复制代码

chuchuliwu · 发表于 2024-12-23 12:20

thy645 发表于 2024-12-19 16:09

感谢，看懂啦

		自动登录	找回密码
密码			免费注册

[求助] 多sheet根据条件合并计算