多个文件夹内图片插入

3000stone

做了一个项目，主文件夹名字是不固定的，里边子文件夹的名字是固定的，但子文件夹图片名字是不固定的。我想把图片按子文件夹名称插入execl里，方便打印。一次可以可以插入一个主文件夹里的就可以，那位大哥给个方法？

liulang0808

https://club.excelhome.net/threa ... tml?_dsign=15791c27
https://club.excelhome.net/threa ... tml?_dsign=73cffde5
楼主可以参考下的

3190496160

这个问题，看似简单，其实，单元格位置判断就比较烧脑，先留个记号吧

3190496160

Sub 插入图片()
Application.ScreenUpdating = False
Dim arr()
Dim fs As Object
Set fs = CreateObject("Scripting.FileSystemObject")
Set f = fs.getfolder(ThisWorkbook.Path & "\41900110005\")
For Each fd In f.subfolders
    n = n + 1
    ReDim Preserve arr(1 To n)
    arr(n) = fd.Name
Next
Set f = Nothing
Set fs = Nothing
With Sheets("sheet1")
    Dim shp As Shape
    For Each shp In .Shapes
        If shp.TopLeftCell.Column < 3 Then shp.Delete
    Next shp
    x = 2: y = 1
    For i = 1 To n
        f = Dir(ThisWorkbook.Path & "\41900110005\" & arr(i) & "\*.jpg")
        Do While f <> ""
            fss = ThisWorkbook.Path & "\41900110005\" & arr(i) & "\" & f
            If y > 2 Then
                y = 1
                x = x + 1
            End If
            .Cells(x, y).Select
            .Pictures.Insert(fss).Select
            Selection.Placement = xlMoveAndSize
            With Selection.ShapeRange
              Selection.ShapeRange.LockAspectRatio = msoFalse
                 .Top = Cells(x, y).Top + 1
                 .Left = Cells(x, y).Left + 1
                 .Width = Cells(x, y).Width
                 .Height = Cells(x, y).Height
             End With
             y = y + 1
        f = Dir
        Loop
        x = x + 2
        y = 1
    Next i
End With
Application.ScreenUpdating = True
MsgBox "ok!"
End Sub

3190496160

41900110005.rar (672 KB, 下载次数: 13)

2024-12-11 15:48 上传

点击文件名下载附件

gwjkkkkk

Option Compare Text
Option Explicit
Sub test()
    Dim br(), i&, j&, r&, f As Object, ff As Object, p$, dic As Object, vKey, pic As Picture
   
    Application.ScreenUpdating = False
    Set dic = CreateObject("Scripting.Dictionary")
   
    p = ThisWorkbook.Path & "\41900110005\"
    For Each ff In CreateObject("Scripting.FileSystemObject").GetFolder(p).subfolders
        dic(ff.Name) = Empty: r = 0: Erase br
        For Each f In CreateObject("Scripting.FileSystemObject").GetFolder(ff.Path).Files
            If f.Name Like "*.jpg" Then
                r = r + 1
                ReDim Preserve br(1 To r)
                br(r) = f.Path
            End If
        Next
        dic(ff.Name) = transArrToRow(br, 2, 1, UBound(br))
    Next
   
    ActiveSheet.Cells.Delete
    r = 0: Columns("A:B").ColumnWidth = 36.75
    For Each vKey In dic.keys
        r = r + 1
        Cells(r, 1) = vKey
        br = dic(vKey)
        For i = 1 To UBound(br)
            r = r + 1
            Rows(r).RowHeight = 148.5
            For j = 1 To UBound(br, 2)
                If Len(br(i, j)) Then
                    Set pic = ActiveSheet.Pictures.Insert(br(i, j))
                    pic.ShapeRange.LockAspectRatio = msoFalse
                    pic.Placement = xlMoveAndSize
                    With Cells(r, j)
                        pic.Left = .Left + 2: pic.Top = .Top + 2
                        pic.Height = .Height - 4: pic.Width = .Width - 4
                    End With
                End If
            Next j
        Next i
    Next
   
    Application.ScreenUpdating = True
    Beep
End Sub
Function transArrToRow(ByVal ar, ByVal iCutNum&, _
    ByVal iStartCol&, ByVal iEndCol&) As Variant()
  
    Dim br, j&, n&, y&, x&, iColSize&
   
    If iStartCol < LBound(ar) Then iStartCol = LBound(ar)
    If iEndCol > UBound(ar) Then iEndCol = UBound(ar)

    n = -(Int(-(iEndCol - iStartCol + 1) / iCutNum))
    iColSize = IIf(iEndCol - iStartCol + 1 < iCutNum, iEndCol - iStartCol + 1, iCutNum)
    ReDim br(1 To n, 1 To iColSize)

    n = 0
    For j = iStartCol To iEndCol
        n = n + 1
        y = -Int(-n / iCutNum)
        x = IIf(n Mod iCutNum = 0, iCutNum, n Mod iCutNum)
        br(y, x) = ar(j)
    Next j

    transArrToRow = br
End Function

gwjkkkkk

参与一下。。。

3000stone

谢谢大哥，效果还是可以的。

欧陈养

gwjkkkkk 发表于 2024-12-11 19:36
参与一下。。。

如果想把图片放多几列，怎么处理代码呢

cai2532

gwjkkkkk 发表于 2024-12-11 19:34
Option Compare Text
Option Explicit
Sub test()

效果很理想，值的学习。