请问如何根据excel的内容按txt模板批量生成txt文件？

yui678

excel内AB列为原数据，EF列为处理完的数据，我想把EF列的内容填入到TXT模板里中间一段（页眉页脚的内容不动）

原数据的行数也是不固定的，有多有少，也就意味着EF列的行数也不固定

不知道该如何处理，完全没有思路……
先谢谢了！

gwjkkkkk

Option Explicit
Sub TEST()
    Dim ar, br, cr, i&, j&, strTxt$, strPath$, strFileName$
   
    strPath = ThisWorkbook.Path & "\"
    strFileName = strPath & "模板文件.txt"
    If Dir(strFileName) = "" Then MsgBox "模板文件不存在！": Exit Sub
   
    Application.ScreenUpdating = False
   
    strTxt = ReadFromTextFile(strFileName)
    ar = Split(strTxt, vbCrLf)
    ReDim br(1 To 5)
    br(1) = ar(0): br(5) = ar(UBound(ar))
   
    ar = [A1].CurrentRegion.Value
    ReDim cr(1 To UBound(ar))
    For i = 1 To UBound(ar)
        cr(i) = ar(i, 1) & vbTab & ar(i, 2)
    Next i
    br(3) = Join(cr, vbCrLf)
   
    WriteToTextFile strFileName, Join(br, vbCrLf)
    Application.ScreenUpdating = True
    Beep
End Sub

Function ReadFromTextFile$(ByVal strFullName$, Optional ByVal strCharSet$ = "UTF-8")
    With CreateObject("ADODB.Stream")
        .Type = 2
        .Mode = 3
        .Charset = strCharSet
        .Open
        .LoadFromFile strFullName
        ReadFromTextFile = .ReadText
        .Close
    End With
End Function
Function WriteToTextFile(ByVal strFullName$, ByVal strTxt$, Optional ByVal strCharSet$ = "UTF-8")
    With CreateObject("ADODB.Stream")
        .Type = 2
        .Mode = 3
        .Charset = strCharSet
        .Open
        .WriteText strTxt
        .SaveToFile strFullName, 2
        .flush
        .Close
    End With
End Function

gwjkkkkk

请参考。。。

yui678

gwjkkkkk 发表于 2024-11-17 18:07
请参考。。。

额。。。请问怎么用啊？我刚接触excel的编程不久。。。。。。。

赵桢0611

yui678 发表于 2024-11-18 22:43
额。。。请问怎么用啊？我刚接触excel的编程不久。。。。。。。

更改一下数据，运行一下TEST宏，去模板文件，查看一下变动

yui678

gwjkkkkk 发表于 2024-11-17 18:07
请参考。。。

请问我稍作修改后，导出的txt多了很多空行是啥原因啊？似乎trim没起作用？

yui678

赵桢0611 发表于 2024-11-18 22:55
更改一下数据，运行一下TEST宏，去模板文件，查看一下变动

已经能运行了，多谢！

gwjkkkkk

已经运行了，我不回复了。。。

yui678

gwjkkkkk 发表于 2024-11-19 18:17
已经运行了，我不回复了。。。

别啊~~~~~~~~~空行问题还是没解决。。。

gwjkkkkk

yui678 发表于 2024-11-19 19:27
别啊~~~~~~~~~空行问题还是没解决。。。

老实说，还真看不懂你的文件，新下载的文件有两个文件，都有固定内容，是不是有两个模板？生成的文件名怎么样的？EXCEL中有两段不连续的数据，应该取那些数据，都是有疑义的，建议详细描述一下，并附件一下完成结果，如里看得懂我明天再回复你。