VBA初学者向大师们求教

金樽邀月

【明细】工作表中有若干员工，签订了多期劳动合同，我想在【统计】工作表中，获取每名员工合同开始的最早日期、合同结束的最晚日期。

Qs18

1. Sub qs()
   
2.     Dim arr, i, dic
   
3.     Set dic = CreateObject("scripting.dictionary")
   
4.     arr = Sheet1.Range("a1").CurrentRegion.Value
   
5.     ReDim brr(1 To UBound(arr), 1 To 4)
   
6.     For i = 2 To UBound(arr)
   
7.         s = arr(i, 1)
   
8.         If Not dic.exists(s) Then
   
9.             m = m + 1
   
10.             dic(s) = m
    
11.             For j = 1 To 4
    
12.                 brr(m, j) = arr(i, j)
    
13.             Next
    
14.         Else
    
15.             r = dic(s)
    
16.             If CDate(brr(r, 3)) > CDate(arr(i, 3)) Then brr(r, 3) = CDate(arr(i, 3))
    
17.             If CDate(brr(r, 4)) < CDate(arr(i, 4)) Then brr(r, 4) = CDate(arr(i, 4))
    
18.         End If
    
19.     Next
    
20.     Sheet2.Range("a2").Resize(m, 4) = brr
    
21. End Sub
    

复制代码

Qs18

试试.............

xlj310

=TAKE(SORT(FILTER(明细!C:C,(明细!$A:$A=$A2)*(明细!$B:$B=$B2))),-1^(COLUMN(B1)))
公式向右和向下填充即可。

Qs18

试试............

金樽邀月

Qs18 发表于 2024-11-13 16:42
试试............

感谢老师的热心解答，我后来想到的一个笨办法是仍然使用VLOOKUP，先对明细表按工号、合同时间进行排序，这样最早的日期要么排在第一行，要么排在最后一行，VLOOKUP第四个参数选0的话匹配第一个数值，不添加第四个参数的话，匹配最后一个数值。我后面慢慢学习消化老师的代码。

金樽邀月

xlj310 发表于 2024-11-13 16:42
=TAKE(SORT(FILTER(明细!C:C,(明细!$A:$A=$A2)*(明细!$B:$B=$B2))),-1^(COLUMN(B1)))
公式向右和向下填充 ...

谢谢老师的解答，老师的函数公式水平一流。

Qs18

金樽邀月 发表于 2024-11-13 17:10
感谢老师的热心解答，我后来想到的一个笨办法是仍然使用VLOOKUP，先对明细表按工号、合同时间进行排序， ...

也是一个好的方法

gwjkkkkk

Option Explicit
Sub test1()
    Dim i&, cnn As Object, rst As Object, strSQL$, strPath$
   
    Set cnn = CreateObject("ADODB.Connection")
    strPath = ThisWorkbook.FullName
   
    Select Case Application.Version * 1
        Case Is <= 11
            cnn.Open "Provider=Microsoft.JET.OLEDB.4.0;Data Source=" & strPath & ";Extended Properties='Excel 8.0;HDR=YES;IMEX=0'"
        Case Is >= 12
            cnn.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strPath & ";Extended Properties='Excel 12.0;HDR=YES;IMEX=0'"
    End Select
   
    strSQL = "SELECT 工号,姓名,min(合同开始日期) AS 合同开始最早日期,max(合同结束日期) AS 合同结束最晚日期 FROM [明细$] " & _
        "GROUP BY 工号,姓名"
    Set rst = cnn.Execute(strSQL)
   
    With ThisWorkbook.Sheets(2)
        .Cells.Clear
        For i = 0 To rst.Fields.Count - 1
            .Cells(1, i + 1) = rst.Fields(i).Name
        Next i
        .Range("A2").CopyFromRecordset rst
        .Cells.EntireColumn.AutoFit
    End With
   
    rst.Close: cnn.Close
    Set rst = Nothing: Set cnn = Nothing
    Beep
End Sub

gwjkkkkk

请参考附件。。。