进销存查询无效

yeyq9449

点击查询，代码好像能运行，跳出“查询结束”，但是没取到数据，是不是哪里的格式有问题？

小白先感谢下大家！

扑腾

查询结果是要显示指定期间单号呢还是所有内容？

ykcbf1100

代码明显是Ai写的。

看了一下数据，单位是是金华地区的，估计楼主也是金华人，看在老乡的份上，我新写一个吧。

ykcbf1100

新写一个吧。

1. Sub ykcbf()   '//2024.11.13
   
2.     Application.ScreenUpdating = False
   
3.     With Sheets("入库明细")
   
4.         r = .Cells(Rows.Count, 3).End(3).Row
   
5.         arr = .[c1].Resize(r, 15)
   
6.     End With
   
7.     ReDim brr(1 To r, 1 To 15)
   
8.     With Sheets("记录表1")
   
9.         st = .[a1].Value
   
10.         rq1 = .[b1].Value
    
11.         rq2 = .[c1].Value
    
12.         .UsedRange.Offset(2).ClearContents
    
13.         For i = 6 To UBound(arr)
    
14.             If arr(i, 12) = st Then
    
15.                 If arr(i, 2) >= rq1 And arr(i, 2) <= rq2 Then
    
16.                     m = m + 1
    
17.                     For j = 1 To UBound(arr, 2)
    
18.                         brr(m, j) = arr(i, j)
    
19.                     Next
    
20.                     brr(m, 4) = Split(brr(m, 4), Chr(10))(0)
    
21.                     If brr(m, 5) <> Empty Then brr(m, 5) = Split(brr(m, 5), Chr(10))(0)
    
22.                 End If
    
23.             End If
    
24.         Next
    
25.         .[a3].Resize(m, 15) = brr
    
26.     End With
    
27.     Application.ScreenUpdating = True
    
28.     MsgBox "OK！"
    
29. End Sub
    
30. 
    

复制代码

yeyq9449

ykcbf1100 发表于 2024-11-13 11:01
新写一个吧。

感谢老乡帮助

风过天涯

原来那段AI写的代码也不是一无是处，最大的问题是你for循环A列，但是A列是空的，要带着自己的思考去寻求别人帮助，才能成长

yeyq9449

风过天涯 发表于 2024-11-13 13:10
原来那段AI写的代码也不是一无是处，最大的问题是你for循环A列，但是A列是空的，要带着自己的思考去寻求别 ...

感谢大大指点~

ykcbf1100

风过天涯 发表于 2024-11-13 13:10
原来那段AI写的代码也不是一无是处，最大的问题是你for循环A列，但是A列是空的，要带着自己的思考去寻求别 ...

Ai写的代码不是不能用，问题在于它的代码多是直接单元格操作的，数据处理速度偏慢。用数组更合理。

gwjkkkkk

Option Explicit
Sub test1()
    Dim i&, cnn As Object, rst As Object, strSQL$, strPath$
   
    Set cnn = CreateObject("ADODB.Connection")
    strPath = ThisWorkbook.FullName
    Select Case Application.Version * 1
        Case Is <= 11
            cnn.Open "Provider=Microsoft.JET.OLEDB.4.0;Data Source=" & strPath & ";Extended Properties='Excel 8.0;HDR=YES;IMEX=0'"
        Case Is >= 12
            cnn.Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & strPath & ";Extended Properties='Excel 12.0;HDR=YES;IMEX=0'"
    End Select
   
    strSQL = "SELECT * FROM [入库明细$C5:N] WHERE 入库日期>=#" & [b1].Value & "# And 入库日期<=#" & [c1].Value & "#" & _
        " AND 供应商名称='" & [A1].Value & "'"
    Set rst = cnn.Execute(strSQL)
   
    With ThisWorkbook.Sheets(2)
        .[A1].CurrentRegion.Offset(2).ClearContents
        .Range("A3").CopyFromRecordset rst
    End With
   
    rst.Close: cnn.Close
    Set rst = Nothing: Set cnn = Nothing
    Beep
End Sub

gwjkkkkk

参与一下。。。