多条件匹配后通过对应数值再判断指定结果

爱晴海

请教老师
多条件匹配后通过对应数值再判断指定结果。具体内容见表格附件

dambcer

Excel PQ处理，如不需要PQ，请忽略。。。

edwin11891

克重规则不明确，会出现多解，比如：50-80,55-105，60-100，80以下等。
克重区间不重叠的话，就是一个GROUPBY函数的事。

edwin11891

问题不是很复杂，但是还是拉了个火车：

1. =LET(t,DROP(REDUCE("",E3:E68,LAMBDA(x,y,VSTACK(x,IF(ISNUMBER(FIND("以下",y)),HSTACK(0,--LEFT(y,LEN(y)-2)),IF(ISNUMBER(FIND("以上",y)),HSTACK(--LEFT(y,LEN(y)-2),300),--TEXTSPLIT(y,"-")))))),1),Sa,BYROW(J4:M6,CONCAT),Sb,BYROW(A3:D68,CONCAT),Res,MAP(Sa,SEQUENCE(ROWS(Sa)),LAMBDA(x,y,LET(Qa,FILTER(HSTACK(t,F3:F68),x=Sb),Qb,IF((CHOOSECOLS(Qa,1)<=OFFSET(N3,y,))*(CHOOSECOLS(Qa,2)>=OFFSET(N3,y,)),CHOOSECOLS(Qa,3),""),FILTER(Qb,Qb<>"")))),Res)

复制代码

李贵濮

插个眼
思路
50以下 就是<=49
50-80 就是 <=80 ,>=50
80以上 就是 >=81
以此类推
然后利用辅助列第一步，（以改为-）
得到想要的数值
vba:

Sub li()
    For m = 4 To 6
    For n = 3 To 68
    If Cells(n, 5) = Cells(m, 19) Then
    If Cells(n, 9) > Cells(n, 10) Then
    If Cells(m, 20) >= Cells(n, 10) And Cells(m, 20) <= Cells(n, 9) Then
    Cells(m, 21) = Cells(n, 11)
    End If
   ElseIf Cells(n, 9) < Cells(n, 10) Then
   If Cells(m, 20) <= Cells(n, 10) And Cells(m, 20) >= Cells(n, 9) Then
    Cells(m, 21) = Cells(n, 11)
    End If
    End If
    End If
    Next
    Next
   
End Sub

edwin11891

优化一下公式：

1. =LET(t,DROP(REDUCE("",E3:E68,LAMBDA(x,y,VSTACK(x,--TEXTSPLIT(SUBSTITUTE(IF(ISNUMBER(FIND("以下",y)),"0-"&LEFT(y,LEN(y)-2),y),"以上","-300"),"-")))),1),Sa,BYROW(J4:M6,CONCAT),Sb,BYROW(A3:D68,CONCAT),Res,MAP(Sa,SEQUENCE(ROWS(Sa)),LAMBDA(x,y,LET(Qa,FILTER(HSTACK(t,F3:F68),x=Sb),Qb,FILTER(CHOOSECOLS(Qa,3),(CHOOSECOLS(Qa,1)<=OFFSET(N3,y,))*(CHOOSECOLS(Qa,2)>=OFFSET(N3,y,))),Qb))),Res)

复制代码

mykitami

=LET(a,--DROP(REDUCE("",IFS(ISNUMBER(FIND("以下",$E$3:$E$68)),"0-"&SUBSTITUTE($E$3:$E$68,"以下",),ISNUMBER(FIND("以上",$E$3:$E$68)),SUBSTITUTE($E$3:$E$68,"以上",)&"-999",1,$E$3:$E$68),LAMBDA(x,y,VSTACK(x,TEXTSPLIT(y,"-",,1)))),1)+{1,0}%,FILTER($F$3:$F$68,($A$3:$A$68=J4)*($B$3:$B$68=K4)*($C$3:$C$68=L4)*($D$3:$D$68=M4)*BYROW(a,LAMBDA(z,MEDIAN(z,N4)=N4))))

爱晴海

edwin11891 发表于 2024-11-6 19:28
克重规则不明确，会出现多解，比如：50-80,55-105，60-100，80以下等。
克重区间不重叠的话，就是一个GROU ...

多条件下都是不一样的克重

edwin11891

爱晴海 发表于 2024-11-8 08:51
多条件下都是不一样的克重

公式在6楼，供参考。

爱晴海

edwin11891 发表于 2024-11-6 20:54
优化一下公式：

谢谢，我的是2016，优化的不支持。