多表格，查询后返回对应行数据

笨逗逗

比如我有多个操作表，至少4个SHEET以上.汇总表和操作01/操作02/操作03。。。。。(最多不会超过操作09)

有1个汇总表
汇总表，根据序号，去各个表查询，如果查到返回该行的某几个单元格，我用每个单元格IF和VLOOKUP查询，数据量算法太大，容易卡
COUNTIF和MATCH，(如果不在第一个表，就if第2个表，if第三个表........到IF操作09)公式太长了
IF(COUNTIF(操作01!$A:$A,$A35)=1,INDEX(操作01!$A:$BB,MATCH($A35,操作01!$A:$A,0),{2,5,7,8,9,11,12,14,15,16}),IF(COUNTIF(操作02!$A:$A,$A35)=1。。。。。。直到IF操作09

我再网上搜VLOOKUP($K7,INDIRECT(LOOKUP(1,0/COUNTIF(INDIRECT("操作0"&ROW($1:$6)&"!$A:$A"),$K7),"操作0"&ROW($1:$6))&"!$A:$BB"),3,0))的这个好像公式很短，但是没看懂！

各位大神有没有简化的公式写法和不太占用资源的函数算法？汇总表序号从1开始按顺序不会重复，操作01-09的序号也不会重复

比如
表1：1-10，17-28，39-45
表2：11-14，29-30
表3：15-16，31-38，46-50
表4-表9：。。。。。等等

hxj119

上传附件，上传附件，上传附件！！！

mjm04

先把 各个分表 合并成一张 内存总表（虚拟的、是个内存数组），再在 这个总表上查找引用，会快很多的

办法很多，不过没附件就没办法的

笨逗逗

hxj119 发表于 2024-10-31 14:16
上传附件，上传附件，上传附件！！！

大神附件上传了，受累帮忙优化下吧~~公式太长太卡了，如果变为共享文档以后，共享文档无法使用数组函数

笨逗逗

mjm04 发表于 2024-10-31 15:03
先把 各个分表 合并成一张 内存总表（虚拟的、是个内存数组），再在 这个总表上查找引用，会快很多的

办 ...

大神附件上传了，受累帮忙优化下吧~~公式太长太卡了，如果变为共享文档以后，共享文档无法使用数组函数

zjnfxxh

不就是合并报表吗？  pq 或  vba是最好用的工具
函数：A4==LET(a,VSTACK(操作01:操作06!A4:AZ100),b,FILTER(a,TAKE(a,,1)<>""),CHOOSECOLS(b,{1,2,3,4,5,6,7,8,9,10,11,14,16,18,51}))

你是那块小饼干

1. =REDUCE("",SHEETSNAME(,1,1),LAMBDA(X,Y,VSTACK(X,INDIRECT(Y&"!B4:P"&SUM(COUNTA(INDIRECT(Y&"!B:B")),2)))))

复制代码

WPS版本 只合并B到P列

solextrade

把B3 填上 操作 2字，数组公式，右拖下拖，B4
=VLOOKUP($A4,INDIRECT("操作0"&MATCH(1,COUNTIF(INDIRECT("操作0"&ROW($1:$6)&"!A:A"),$A4),)&"!A:BB"),MATCH(B$3,操作01!$3:$3,),)

mjm04

汇总并查询
支持：客户名称 或  委托单号 或  提单号 或 船名 四种查询方式；

=LET(_汇总,VSTACK(IFERROR(FILTER(操作01!A4:AX1000,操作01!A4:A1000<>""),""),IFERROR(FILTER(操作02!A4:AX1000,操作02!A4:A1000<>""),""),IFERROR(FILTER(操作03!A4:AX1000,操作03!A4:A1000<>""),""),IFERROR(FILTER(操作04!A4:AX1000,操作04!A4:A1000<>""),""),IFERROR(FILTER(操作05!A4:AX1000,操作05!A4:A1000<>""),""),IFERROR(FILTER(操作06!A4:AX1000,操作06!A4:A1000<>""),"")),_返回区域,CHOOSECOLS(_汇总,1,2,3,4,5,6,7,8,9,10,11,14,16,17,18,50),_客户列,CHOOSECOLS(_返回区域,3),_委托单号列,CHOOSECOLS(_返回区域,4),_提单号列,CHOOSECOLS(_返回区域,5),_船名列,CHOOSECOLS(_返回区域,6),FILTER(_返回区域,((_客户列=$E$1)+(_委托单号列=$E$1)+(_提单号列=$E$1)+(_船名列=$E$1))))



===============================================================

只汇总，不查询

=LET(_汇总,VSTACK(IFERROR(FILTER(操作01!A4:AX1000,操作01!A4:A1000<>""),""),IFERROR(FILTER(操作02!A4:AX1000,操作02!A4:A1000<>""),""),IFERROR(FILTER(操作03!A4:AX1000,操作03!A4:A1000<>""),""),IFERROR(FILTER(操作04!A4:AX1000,操作04!A4:A1000<>""),""),IFERROR(FILTER(操作05!A4:AX1000,操作05!A4:A1000<>""),""),IFERROR(FILTER(操作06!A4:AX1000,操作06!A4:A1000<>""),"")),CHOOSECOLS(_汇总,1,2,3,4,5,6,7,8,9,10,11,14,16,17,18,50))


================================================

函数只写到 各分表的1000行，分表超行会漏数据