如何用函数自动汇总工资

gwgha · 发表于 2024-10-30 18:53

本帖最后由 gwgha 于 2024-10-30 19:21 编辑

今天收获很大，距离目标越来越近了。现在的表格如下，见附件sheet1:

怎么自动生成员工的工资？比如冯博的工资应该是D2*E2+D3*E3+...+D10*E10
表的格式如下，如果上表增加或减少了人员的工序等参数，希望可以自动修改工资。
见附件sheet2，最好姓名也可以根据上表自动生成。

有函数可以实现吗？
先谢谢各位大神了。

良良 · 发表于 2024-10-30 19:04

=SUMPRODUCT((Sheet1!$A2:$A65=B1)*Sheet1!$D2:$D65*Sheet1!$E2:$E65)

gadxjyang · 发表于 2024-10-30 19:06

B2：=SUMPRODUCT((Sheet1!$A2:$A65=B1)*(Sheet1!$D2:$D65)*(Sheet1!$E2:$E65)) 右拉

gadxjyang · 发表于 2024-10-30 19:10

B2：=SUM(IF(Sheet1!$A2:$A65=B1,Sheet1!$D2:$D65*Sheet1!$E2:$E65))

gwgha · 发表于 2024-10-30 19:22

良良发表于 2024-10-30 19:04
=SUMPRODUCT((Sheet1!$A2:$A65=B1)*Sheet1!$D2:$D65*Sheet1!$E2:$E65)

感谢，追问一下，姓名如何根据表格内容自动生成？

gwgha · 发表于 2024-10-30 19:22

gadxjyang 发表于 2024-10-30 19:06
B2：=SUMPRODUCT((Sheet1!$A2:$A65=B1)*(Sheet1!$D2:$D65)*(Sheet1!$E2:$E65)) 右拉

感谢，追问一下，姓名如何根据表格内容自动生成？

mykitami · 发表于 2024-10-30 19:38

B1单元格公式，用于姓名自动溢出
=UNIQUE(TOROW(IF(Sheet1!A2:A999<>"",Sheet1!A2:A999,x),2),1)
B2公式，用于工资自动溢出
=MAP(B1#,LAMBDA(x,ROUND(SUMPRODUCT((Sheet1!A2:A999=x)*Sheet1!D2:D999*Sheet1!E2:E999),2)))

良良 · 发表于 2024-10-30 19:54

gwgha 发表于 2024-10-30 19:22
感谢，追问一下，姓名如何根据表格内容自动生成？

B1
=IFERROR(INDEX(Sheet1!$A:$A,MATCH(,COUNTIF($A1:A1,Sheet1!$A2:$A65),)+1),"")
或
=INDEX(Sheet1!$A:$A,SMALL(IF(MATCH(Sheet1!$A2:$A65,Sheet1!$A2:$A65,)=ROW(1:64),ROW(2:65),4^8),COLUMN(A1)))&""
三键，右拉。

华尔街操盘手 · 发表于 2024-10-30 20:04

表2 a1单元格自动生成

=IFERROR(TRANSPOSE(GROUPBY(Sheet1!A1:A65,Sheet1!E1:E65*Sheet1!D1:D65,SUM,3)),"工资")

复制代码

忙到飞起 · 发表于 2024-10-30 20:09

=LET(a,FILTER(Sheet1!$D:$E,Sheet1!$A:$A=Sheet2!B$1),SUM(TAKE(a,,1)*TAKE(a,,-1)))

写的不好

		自动登录	找回密码
密码			免费注册

[求助] 如何用函数自动汇总工资