如何用函数筛选提取前5名学生成绩

chenyonghtc · 发表于 2024-10-17 12:10

请问怎样写公式用什么函数，麻烦大家帮我看看，感谢。 QQ截图20241017120222.jpg

筛选.rar (10.59 KB, 下载次数: 21)

hxj119 · 发表于 2024-10-17 13:06

本帖最后由 hxj119 于 2024-10-17 13:07 编辑

=TAKE(SORT(FILTER(HSTACK(B2:B24,C2:C24,A2:A24),ISNUMBER(C2:C24)),2,-1),5)

复制代码

英语类似的公式

=TAKE(SORT(FILTER(HSTACK(B2:B24,D2:D24,A2:A24),ISNUMBER(C2:C24)),2,-1),5)

复制代码

acbczhhw · 发表于 2024-10-17 13:51

=TRANSPOSE(INDEX($B:$B,MATCH(LARGE($C$2:$C$24,{1,2,3,4,5}),$C:$C)))
我写了个公式，有的正常有的不正常，不知道啥原因

袁勇 · 发表于 2024-10-17 13:53

低版本。

=INDEX($A:$K,MOD(AGGREGATE(14,6,OFFSET($B$2:$B$24,,MATCH($M$2,$C$1:$K$1,))*10^6+ROW($2:$24),$M4),100),MATCH(IF(N$3="分数",$M$2,N$3),$A$1:$K$1,))

复制代码

右拉下拉。

leepoison · 发表于 2024-10-17 13:56

=TAKE(SORT(HSTACK(B2:B24,N(FILTER(C2:K24,C1:K1=M2)),A2:A24),2,-1),5)
=TAKE(SORT(HSTACK(B2:B24,N(FILTER(C2:K24,C1:K1=M11)),A2:A24),2,-1),5)

袁勇 · 发表于 2024-10-17 13:59

M2单元格设数据有效性序列，然后在N3单元格输入公式：

=INDEX($A:$K,MOD(AGGREGATE(14,6,OFFSET($B$2:$B$24,,MATCH($M$2,$C$1:$K$1,))*10^6+ROW($2:$24),$M4),100),MATCH(IF(N$3="分数",$M$2,N$3),$A$1:$K$1,))

复制代码

右拉下拉。如图：

acbczhhw · 发表于 2024-10-17 14:05

hxj119 发表于 2024-10-17 13:06
英语类似的公式

这个公式可以，点赞

wgreen · 发表于 2024-10-17 14:39

#在这里快速=TAKE(SORT(CHOOSECOLS(IF(A2:K24<>"扫描缺考",A2:K24,0),2,3,1),2,-1),5)回复#

acbczhhw · 发表于 2024-10-17 15:32

=TAKE(SORT(CHOOSECOLS(IF(ISTEXT(C2:C24)=FALSE,$A$2:$K$24,0),2,XMATCH(M2,$A$1:$K$1),1),2,-1),5)

hcm19522 · 发表于 2024-10-17 16:23

本帖最后由 hcm19522 于 2024-10-17 16:32 编辑

M3 輸入科目 N4:P8{=OFFSET($A$1,RIGHT(LARGE(($M$2=$C$1:$J$1)*N(+$C$2:$J$24)/1%%+ROW($1:$23),$M4),2),-LOOKUP(1,-MATCH(IF({1,0},$M$2,N$3),$1:$1,)+1))

		自动登录	找回密码
密码			免费注册

[求助] 如何用函数筛选提取前5名学生成绩

评分

评分