吃最多数量苹果问题：双路动态规划（DP）参考解法

shaowu459

初始值k=2和结束值k=20可以单独处理：

shaowu459

公式简要说明如下：
    =REDUCE(  
        HSTACK("2-1-1", B2),       处理初始值k=2，dp[1]为矩阵左上角值
        ROW(3:20),                    循环k的范围[3,20]
        LAMBDA(x, y,
            IF(
                y = 20,MAX(x) + K11,      如果k=20，返回最终结果=矩阵右下角值+x中最大值
                REDUCE(
                    x,                    保留上层循环的结果，继续堆积
                    SEQUENCE(IF(y < 12, y - 2, 20 - y), , IF(y < 12, 2, y - 9)),   根据k计算第2层循环值
                    LAMBDA(m, n,   
                        REDUCE(  
                            m,                    保留上层循环的结果，继续堆积
                            SEQUENCE(n + (y > 11) * (11 - y), , IF(y < 12, 1, y - 10)), 根据k和x1计算第2层循环值
                            LAMBDA(p, q,   
                                VSTACK(
                                    p,                    累计dp数组
                                    HSTACK(
                                        y & -n & -q,                            连接k-x1-x2  
                                        INDEX(B2#, n, y - n) +        提取矩阵中[x1,k-x1]位置的值
                                         (n > q) * INDEX(B2#, q, y - q) +   提取矩阵中[x2,k-x2]位置的值，但只有在x1>x2的时候才保留，否则变成0
                                            MAX(                            对来源的四种状态取dp的最大值
                                                IFNA(
                                                    VLOOKUP(     在累计dp数组p中查找四种状态值
                                                        y - 1 & {0; 1; 0; 1} - n & {0; 0; 1; 1} - q,   
                                                        p,   累计dp数组  
                                                        2,   
                                                    ),  
                                                )  
                                            )  
                                    )  
                                )   
                            )  
                        )
                    )   
                )  
            )  
        )  
    )

cnmlgb9998

不明觉厉！

溺水鱼

新人膜拜大神们！！！

edwin11891

就是喝完一瓶白的，估计也还是理不清！

shaowu459

edwin11891 发表于 2024-10-12 21:52
就是喝完一瓶白的，估计也还是理不清！

喝了没有

小周bim

无法企及的巅峰

小周bim

老师能否看看我刚发的那个帖子，想了很久都没想出公式的解法，我的版本是365

Excel表哥在此

不服不行啊，太 ...太厉害了.......顶礼膜拜

捡回一个小僵尸

超人老师太厉害啦