新函数把原数据重新生成带序号的新数据

SCWYZJ · 发表于 2024-10-11 15:49

求助:l利用新函数把原数据重新生成带序号的新数据（见附件），请老师帮忙着看看，如何写。谢谢

Sabrinalijie · 发表于 2024-10-11 15:51

=REDUCE({"序号","姓名"},B4:B33,LAMBDA(X,Y,IF(Y="",X,VSTACK(X,HSTACK(ROWS(X),Y)))))

复制代码

hugeinfo · 发表于 2024-10-11 15:52

=HSTACK(SEQUENCE(COUNTIF(B4:B10,"<>")),FILTER(B4:B10,B4:B10<>""))

wp231957 · 发表于 2024-10-11 15:57

=HSTACK(SEQUENCE(ROWS(B4:B7)),B4:B7)

你是那块小饼干 · 发表于 2024-10-11 16:04

=HSTACK(SEQUENCE(COUNTA(B4:B7)),B4:B7)

hxj119 · 发表于 2024-10-11 16:17

=LET(a,TOCOL(B4:B10,1),HSTACK(SEQUENCE(ROWS(a)),a))

复制代码

hxj119 · 发表于 2024-10-11 16:23

本帖最后由 hxj119 于 2024-10-11 16:27 编辑

练习reduce

=DROP(REDUCE({0,""},TOCOL(B4:B99,3),LAMBDA(x,y,VSTACK(x,HSTACK(TAKE(x,-1,1)+1,y)))),1)

复制代码

leepoison · 发表于 2024-10-11 16:23

本帖最后由 leepoison 于 2024-10-11 08:27 编辑

=LET(b,B4:B100,a,FILTER(b,b<>""),HSTACK(SEQUENCE(COUNTA(a)),a))

=LET(a,TOCOL(B4:B100,1),HSTACK(SEQUENCE(COUNTA(a)),a))

mykitami · 发表于 2024-10-11 16:35

=LET(xm,UNIQUE(B4:B2000,,1),HSTACK(SEQUENCE(ROWS(xm)),xm))

SCWYZJ · 发表于 2024-10-11 18:24

各位老师太热心了，感谢。我都试了，都可以。

		自动登录	找回密码
密码			免费注册

[求助] 新函数把原数据重新生成带序号的新数据

评分

评分

评分

评分

评分

评分

评分

评分