优化一个字符串提取公式

lsxdlam · 发表于 2024-10-10 14:31

本帖最后由 lsxdlam 于 2024-10-10 15:04 编辑

需要提取前半部分的编号，如图：

目前已有公式是：

=IF(ISODD(MATCH(" ",MIDB(A2,ROW(INDIRECT("1:"&LENB(A2))),1),)),LEFT(A2,MATCH(" ",MIDB(A2,ROW(INDIRECT("1:"&LENB(A2))),1),)-2),LEFT(A2,MATCH(" ",MIDB(A2,ROW(INDIRECT("1:"&LENB(A2))),1),)-1))

复制代码

但这也太费事了，重复计算两三次，太不效率了。并且在平时设计公式的时候经常会遇到类似问题，想知道如果不用辅助列还能有其它优化方式吗？

hxj119 · 发表于 2024-10-10 14:42

本帖最后由 hxj119 于 2024-10-10 15:21 编辑

=REGEXP(A2,"^[\w]+(-\d+)?")

复制代码

更新一下，中括号此处多余了，这样更简洁
=REGEXP(A2,"^\w+(-\d+)?")

ovxyz · 发表于 2024-10-10 14:45

=LEFT(A2,MIN(IFERROR(FIND({"汉字","-汉字"},A2),1000))-1)

autohotey · 发表于 2024-10-10 14:47

=LET(text,A2,spacePos,MATCH(" ",MIDB(text,ROW(INDIRECT("1:"&LENB(text))),1),),
IF(ISODD(spacePos),LEFT(text,spacePos-2),LEFT(text,spacePos-1)))

袁勇 · 发表于 2024-10-10 14:57

=LEFT(A2,MATCH(2,LENB(MID(A2,ROW($1:$254),1)),)-1-ISODD(MATCH(2,LENB(MID(A2,ROW($1:$254),1)),)))

复制代码

pjiang · 发表于 2024-10-10 14:58

，，，，，，，，，，

waternew · 发表于 2024-10-10 14:59

本帖最后由 waternew 于 2024-10-10 15:54 编辑

=INDEX(TEXTSPLIT(SUBSTITUTE(A2,"-汉","汉"),"汉"),,1)

=LET(a,INDEX(TEXTSPLIT(A2,CHAR(ROW($33100:$65100))),,1),IF(RIGHT(a,1)="-",LEFT(A2,LEN(a)-1),a))

pjiang · 发表于 2024-10-10 15:08

waternew 发表于 2024-10-10 14:59
=INDEX(TEXTSPLIT(SUBSTITUTE(A2,"-汉","汉"),"汉"),,1)

他指的是任意汉字，

jiaxianwa · 发表于 2024-10-10 15:10

=SUBSTITUTE(@TEXTSPLIT(A2,"汉")&" ","- "," ")

jiaxianwa · 发表于 2024-10-10 15:10

老板如果觉得可以，请赏个小花花吧，您的鼓励是我最大的动力

		自动登录	找回密码
密码			免费注册

[已解决] 优化一个字符串提取公式

评分

评分

评分