求助

TOM-Q

附件Sheet1的表格需要打印标签，数量大于1的物料需要打印分标签，数量是多少就要打印多少份，总标签为合计数，分标签数量为1，结果见Sheet2的式样。源数据比较多，手工拷贝比较费时间，哪位老师帮忙提供一下宏程序，谢谢

哈喽哈哈1

1. Sub 插入行数()
   
2.     Dim ws As Worksheet
   
3.     Set ws = ThisWorkbook.Sheets("Sheet1")
   
4.    
   
5.     Dim lastRow As Long
   
6.     lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row
   
7.    
   
8.     Dim i As Long
   
9.     Dim splitCount As Long
   
10.     Dim j As Long
    
11.    
    
12.     Application.ScreenUpdating = False
    
13.    
    
14.     For i = lastRow To 2 Step -1
    
15.         ' 使用 Val 函数尝试将单元格的值转换为数字
    
16.         splitCount = Val(ws.Cells(i, 6).Value)
    
17.         If splitCount > 1 Then
    
18.             ' 插入新行，不包括原始行
    
19.             ws.Rows(i + 1).Resize(splitCount).Insert Shift:=xlDown
    
20.             ' 复制原始行到新插入的每一行
    
21.             For j = 1 To splitCount
    
22.                 ws.Rows(i).Copy Destination:=ws.Rows(i + j)
    
23.                 ' 更新新插入的行的第6列数据为1
    
24.                 ws.Cells(i + j, 6).Value = 1
    
25.             Next j
    
26.             ' 注意：我们不更改原始行的第6列数据
    
27.         End If
    
28.     Next i
    
29.    
    
30.     Application.ScreenUpdating = True
    
31. End Sub

复制代码

楼主，试一下这个代码，刚刚我试运行了一下，应该是可以满足你的要求。

longwin

供参考。。。。

Sub test()
Set sh0 = Sheets("sheet1")
Set sh1 = Sheets("sheet3")
sh1.UsedRange.Clear
arr = sh0.[a9].CurrentRegion
sh0.Rows("1:9").Copy sh1.Rows(1)
dqh = 9
For i = 2 To UBound(arr)
dqh = dqh + 1
    sh0.Rows(i + 8).Copy sh1.Rows(dqh)
    If arr(i, 6) > 1 Then
        For j = 1 To arr(i, 6)
            dqh = dqh + 1
            sh0.Rows(i + 8).Copy sh1.Rows(dqh)
            sh1.Cells(dqh, 6) = 1
        Next
    End If
Next
End Sub

quqiyuan

参与一下，仅供参考。。。

quqiyuan

代码如下。。。
Sub test()
    Dim wb As Workbook, sht As Worksheet, sh As Worksheet
    Set wb = ThisWorkbook
    Set sht = wb.Sheets("sheet1")
    Set sh = wb.Sheets("sheet2")
    arr = sht.[a9].CurrentRegion
    ReDim brr(1 To 10000, 1 To UBound(arr))
    For i = 2 To UBound(arr)
        n = n + 1
        For k = 1 To UBound(arr, 2)
            brr(n, k) = arr(i, k)
        Next
        If arr(i, 6) > 1 Then
            For j = 1 To arr(i, 6)
                n = n + 1
                For k = 1 To UBound(arr, 2)
                    brr(n, k) = arr(i, k)
                Next
                brr(n, 6) = 1
            Next
        End If
    Next
    With sh
        .[a9].CurrentRegion.Clear
        .[a9].Resize(, UBound(arr, 2)) = arr
        .[a10].Resize(n, UBound(arr, 2)) = brr
    End With
    Beep
End Sub

gwjkkkkk

Option Explicit
Sub TEST2()
    Dim ar, br, i&, j&, r&, k&
   
    Application.ScreenUpdating = False
   
    ar = Worksheets(1).[A9].CurrentRegion.Value
    ReDim br(1 To UBound(ar) * 10, 1 To UBound(ar, 2))
    For j = 1 To UBound(ar, 2)
        br(1, j) = ar(1, j)
    Next j
    r = 1
   
    For i = 2 To UBound(ar)
        r = r + 1
        For j = 1 To UBound(ar, 2)
            br(r, j) = ar(i, j)
        Next j
        If ar(i, 6) > 1 Then
            For k = 1 To ar(i, 6)
                r = r + 1
                For j = 1 To UBound(ar, 2)
                    br(r, j) = ar(i, j)
                Next j
                br(r, 6) = 1
            Next k
        End If
    Next i
   
    [J9].Resize(r, UBound(br, 2)) = br
    Application.ScreenUpdating = True
    Beep
End Sub

gwjkkkkk

。。。。。。。。

ykcbf1100

参与一下。。。

ykcbf1100

参与一下。。。

TOM-Q

quqiyuan 发表于 2024-10-5 17:56
代码如下。。。
Sub test()
    Dim wb As Workbook, sht As Worksheet, sh As Worksheet

感谢，测试后，可以完成我的任务