如何用简称判断出原来的医院名单

13600903288 · 发表于 2024-9-29 14:37

在附件里B列是一些医院清单，里面包含有医院的全称，有些医院是用简称，那么现在想把那些简称的提取出来，并把它的全称列在C列。
即在C列显示那些名称的每个字（有顺序）被包含在另外一个医院里的那个医院名称。
如“郑大一”里的3个字都按顺序包含在“郑州大学附属第一医院”；
“厦门大学附一”里的6个字也是按顺序包含在厦门大学附属第一医院里。

良良 · 发表于 2024-9-29 19:10

供参考：由全称得到简称。

C2=IFERROR(INDEX(B$2:B$10,MATCH(26,(MMULT(1-ISERR(FIND(MID(B$2:B$10,COLUMN(A:Z),1),B2)),ROW($1:$26)^0))*(B$2:B$10<>B2),)),"")，三键，下拉。

满坛皆为吾师 · 发表于 2024-9-29 19:14

C2下拉，如果同名无需显示，直接加个IF

=@SORTBY(B$2:B$10,BYROW(FIND(MID(B2,SEQUENCE(,LEN(B2)),1),B$2:B$10),COUNT),-1)

复制代码

无关岁月 · 发表于 2024-9-29 19:19

本帖最后由无关岁月于 2024-9-30 06:48 编辑

365

=LET(_a,B2:B10,_b,SORTBY(_a,LEN(_a),-1),XLOOKUP(REGEXREPLACE(_a,"",".*"),_b,_b,,3))

复制代码

你是那块小饼干 · 发表于 2024-9-29 20:54

=@SORT(HSTACK($B$2:$B$10,MMULT(N(ISNUMBER(FIND(MID(B2,SEQUENCE(,LEN(B2)),1),$B$2:$B$10))),SEQUENCE(LEN(B2),,1,0))),2,-1)

复制代码

mykitami · 发表于 2024-9-29 22:18

C2公式
=LET(s,MAP(B2:B10,LAMBDA(x,LET(a,FILTER(B2:B10,BYROW(ISNUMBER(FIND(MID(B2:B10,SEQUENCE(,26),1),x))*1,SUM)=26),b,SORTBY(a,LEN(a)),IF(ROWS(b)>1,TAKE(b,1),"")))),MAP(B2:B10,LAMBDA(y,XLOOKUP(y,s,B2:B10,""))))

13600903288 · 发表于 2024-9-30 09:08

满坛皆为吾师发表于 2024-9-29 19:14
C2下拉，如果同名无需显示，直接加个IF

你好，我发现如果医院简称在上面的，就不行？

13600903288 · 发表于 2024-9-30 09:10

你是那块小饼干发表于 2024-9-29 20:54

你跟3 楼的一样，如果简称的在上面的，就不能满足

13600903288 · 发表于 2024-10-9 10:02

mykitami 发表于 2024-9-29 22:18
C2公式
=LET(s,MAP(B2:B10,LAMBDA(x,LET(a,FILTER(B2:B10,BYROW(ISNUMBER(FIND(MID(B2:B10,SEQUENCE(,26), ...

看不懂公式啊，结果是我所要的，

nationldb · 发表于 2024-10-9 23:03

13600903288 发表于 2024-10-9 10:02
看不懂公式啊，结果是我所要的，

LAMBDA这是office365新增加的函数，挺NB的，可以自定义公式

		自动登录	找回密码
密码			免费注册

[求助] 如何用简称判断出原来的医院名单

评分