拼半天也没拼成功，想看一下高手代码

wp231957

数据源在左侧  想拼成右侧的哪一种 都可以
有高手给出GROUPBY的办法了，这个超简单，那么堆叠+REDUCE的方案 有吗

leepoison

=GROUPBY(F5:G13,H5:H13,SUM,0,0)

wp231957

leepoison 发表于 2024-9-25 15:49
=GROUPBY(F5:G13,H5:H13,SUM,0,0)

哦，原来是他的活啊   那用各种堆叠和循环呢

ovxyz

=GROUPBY(F4:G13,H4:H13,SUM,3,0)
已经有人回复了，
既然你也提了别的问题，如果没有这个函数，
就用unique结合sumifs
=UNIQUE(F5:G13)
=SUMIFS($H$5:$H$13,$F$5:$F$13,T5,$G$5:$G$13,U5)

hxj119

1. =LET(a,SORT(UNIQUE(F5:G13),1,1),REDUCE(F4:H4,SEQUENCE(ROWS(a)),LAMBDA(x,y,VSTACK(x,HSTACK(INDEX(a,y,),SUM(FILTER(H5:H13,(F5:F13=INDEX(a,y,1))*(G5:G13=INDEX(a,y,2)))))))))

复制代码

一个公式reduce堆叠

wp231957

ovxyz 发表于 2024-9-25 15:52
=GROUPBY(F4:G13,H4:H13,SUM,3,0)
已经有人回复了，
既然你也提了别的问题，如果没有这个函数，

你这貌似用到了辅助单元格吧

如果不用辅助，我这样写成功了，
=LET(a,SORT(UNIQUE(F5:G13)),VSTACK({"名称","物品","数量"},HSTACK(a,SUMIFS(H5:H13,F5:F13,CHOOSECOLS(a,1),G5:G13,CHOOSECOLS(a,2)))))
公式虽然不短，但是容易理解

ovxyz

wp231957 发表于 2024-9-25 16:18
你这貌似用到了辅助单元格吧

如果不用辅助，我这样写成功了，

很好，既然懂新函数，那就好处理了。

你是那块小饼干

1. =GROUPBY(F4:G13,H4:H13,SUM,3,0)

复制代码

1. =LET(T,F5:F13,_T,UNIQUE(T),REDUCE({"名称","物品","数量"},_T,LAMBDA(X,Y,LET(_X,FILTER(G5:H13,Y=T,""),IFNA(VSTACK(X,HSTACK(Y,GROUPBY(CHOOSECOLS(_X,1),CHOOSECOLS(_X,2),SUM,0,0))),"")))))

复制代码

1. =LET(T,F5:F13,_T,UNIQUE(T),REDUCE({"名称","物品","数量"},_T,LAMBDA(X,Y,VSTACK(X,IFNA(HSTACK(Y,{"桌椅";"板凳";"沙发"},SUMIFS(H5:H13,F5:F13,Y,G5:G13,{"桌椅";"板凳";"沙发"})),Y)))))

复制代码

zpy2

//select * from 分组求和原始数据 limit 20;
select 名称,物品,sum(数量) from 分组求和原始数据 group by 名称,物品;
select udf_clean_rpt_ent(名称,'a') 名称,物品,sum(数量) from 分组求和原始数据 group by 名称,物品;
create temp table aa as
select 名称 from 分组求和原始数据 group by 名称;
create temp table bb as
select 物品 from 分组求和原始数据 group by 物品;
select 名称,物品,sum(数量) As 小计 from aa,bb left join 分组求和原始数据 using(名称,物品) group by 名称,物品;

3种视图

wp231957

zpy2 发表于 2024-9-26 09:50
//select * from 分组求和原始数据 limit 20;
select 名称,物品,sum(数量) from 分组求和原始数据 group b ...

是wps吗  sql应用没那么宽   要求表格必须十分标准