关于FILTER查找多列范围的公式简化的问题

bochong · 发表于 2024-9-24 18:34

有一个公式，不知道有没有高手可以简化一下：

=TRANSPOSE(FILTER(Sheet1!A:A,(Sheet1!B:B=A2)+(Sheet1!C:C=A2)+(Sheet1!D:D=A2)+(Sheet1!E:E=A2)+(Sheet1!F:F=A2)+(Sheet1!G:G=A2)+(Sheet1!H:H=A2)+(Sheet1!I:I=A2)+(Sheet1!J:J=A2)+(Sheet1!K:K=A2)+(Sheet1!L:L=A2)+(Sheet1!M:M=A2)+(Sheet1!N:N=A2)+(Sheet1!O:O=A2)+(Sheet1!P:P=A2)+(Sheet1!Q:Q=A2)+(Sheet1!R:R=A2)+(Sheet1!S:S=A2)+(Sheet1!T:T=A2)+(Sheet1!U:U=A2)+(Sheet1!V:V=A2)+(Sheet1!W:W=A2)>0))

只有当对应的B列到W列中至少有一个单元格与A2的值相等时，A列中的相应行才会被包含在结果中。这个公式中还是有很多重复的内容，想简化。但是我尝试过几种简化的方式，结果结果都是错的。

edwin11891 · 发表于 2024-9-24 19:22

本帖最后由 edwin11891 于 2024-9-24 19:25 编辑

稍简化一点，期待大神：

=TRANSPOSE(FILTER(sheet1!A1:A200,BYROW(sheet1!B1:W200,LAMBDA(x,SUM(XLOOKUP(A2,x,MAKEARRAY(1,COLUMNS(A1:C1),LAMBDA(y,z,1)),0,0))))))

复制代码

part98 · 发表于 2024-9-24 19:27

=TRANSPOSE(FILTER(Sheet1!A:A,BYROW(Sheet1!B:W=A2,OR)))

edwin11891 · 发表于 2024-9-24 19:30

本帖最后由 edwin11891 于 2024-9-24 19:33 编辑

再简化一点：

=FILTER(sheet1!A1:A200,BYROW(sheet1!B1:W200,LAMBDA(x,SUM(N(x=A2)))))

复制代码

丢丢表格 · 发表于 2024-9-24 19:37

edwin11891 发表于 2024-9-24 19:22
稍简化一点，期待大神：

=TRANSPOSE(FILTER(A:A,BYROW(B:W,LAMBDA(X,OR(X=A2)))))

浮生若梦~~~ · 发表于 2024-9-24 20:15

=CONCAT(IF(B:W=A2,A:A,""))

edwin11891 · 发表于 2024-9-24 20:21

丢丢表格发表于 2024-9-24 19:37
=TRANSPOSE(FILTER(A:A,BYROW(B:W,LAMBDA(X,OR(X=A2)))))

1. 应用整列方式，把我的新版WPS（18157×64版）直接连续崩溃了三次。

2. OR函数不能得到数组，所以我一般比较排斥使用。

秃头发师 · 发表于 2024-9-24 20:33

=UNIQUE(TOROW(IF(B1:W100=A2,A1:A100,a),3),TRUE)

bochong · 发表于 2024-9-24 21:37

不知道为啥，上面的代码复制到原位置，没有一个能用。而且有好几个代码让我软件直接死机崩溃。

bochong · 发表于 2024-9-24 21:38

edwin11891 发表于 2024-9-24 20:21
1. 应用整列方式，把我的新版WPS（18157×64版）直接连续崩溃了三次。
2. OR函数不能得到数组，所以 ...

没错，这个代码我也直接崩溃掉了

		自动登录	找回密码
密码			免费注册

关于FILTER查找多列范围的公式简化的问题

评分