EXCEL如何在下拉菜单中一边输入一边筛选

martin0915 · 发表于 2024-9-19 09:31

本帖最后由 martin0915 于 2024-9-19 10:00 编辑

在excel中制作的下来菜单内容比较多，寻找起来比较麻烦，可以不可以输入关键词，在下拉菜单中筛选，再选择。
就像下图这样

3190496160 · 发表于 2024-9-19 09:44

vba文本框控件结合列表框控件可以实现，前提是上传你的附件，具体描述你的需求

martin0915 · 发表于 2024-9-19 10:00

3190496160 发表于 2024-9-19 09:44
vba文本框控件结合列表框控件可以实现，前提是上传你的附件，具体描述你的需求

谢谢，你好，附件已经上传。

饮冰e士 · 发表于 2024-9-19 10:50

WPS很方便。

martin0915 · 发表于 2024-9-19 11:08

饮冰e士发表于 2024-9-19 10:50
WPS很方便。

你好，我这边使用的是office，做出来的是需要点击右边的倒三角，而且不能在列表中筛选，不是你那样子的

沈默00 · 发表于 2024-9-19 11:13

本帖最后由沈默00 于 2024-9-19 11:16 编辑

VBA做个控件跟随好了

martin0915 · 发表于 2024-9-19 11:15

沈默00 发表于 2024-9-19 11:13
VBA做个控件跟随好了

尴尬了，我不会

3190496160 · 发表于 2024-9-23 09:13

Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
With ListBox1
For i = 0 To .ListCount - 1
      If .Selected(i) = True Then
         ActiveCell = .List(i, 0)
         Exit For
      End If
Next i
End With
TextBox1.Text = ""
TextBox1.Visible = False
ListBox1.Clear
ListBox1.Visible = False
End Sub

Private Sub TextBox1_Change()
zd = TextBox1.Text
Dim ar As Variant
Dim i As Long, r As Long
Dim d As Object
Set d = CreateObject("scripting.dictionary")
With Sheets("停线明细")
r = .Cells(Rows.Count, 2).End(xlUp).Row
ar = .Range("c1:c" & r)
End With
For i = 2 To UBound(ar)
If ar(i, 1) <> "" Then
      If InStr(ar(i, 1), zd) > 0 Then
         d(ar(i, 1)) = ""
      End If
End If
Next i
With ListBox1
.Visible = True
.Top = ActiveCell.Top + 15
.Left = ActiveCell.Left + 150
.List = d.keys
.Width = 200
.Height = 400
End With
End Sub

Private Sub Worksheet_SelectionChange(ByVal T As Range)
If T.Row > 2 And T.Column = 16 Then
Dim ar As Variant
Dim i As Long, r As Long
Dim d As Object
Set d = CreateObject("scripting.dictionary")
With Sheets("停线明细")
      r = .Cells(Rows.Count, 2).End(xlUp).Row
      ar = .Range("c1:c" & r)
End With
For i = 2 To UBound(ar)
      If ar(i, 1) <> "" Then
         d(ar(i, 1)) = ""
      End If
Next i
With TextBox1
      .Visible = True
      .Top = T.Top
      .Left = T.Left
      .Activate
End With
With ListBox1
      .Visible = True
      .Top = ActiveCell.Top + 15
      .Left = ActiveCell.Left + 150
      .List = d.keys
      .Width = 200
      .Height = 400
End With
Else
TextBox1.Text = ""
TextBox1.Visible = False
ListBox1.Clear
ListBox1.Visible = False
End If
End Sub

3190496160 · 发表于 2024-9-23 09:14

文本框输入关键字模糊搜索，列表框中双击录入

生産管理板 .rar (29.13 KB, 下载次数: 3)

		自动登录	找回密码
密码			免费注册

[求助] EXCEL如何在下拉菜单中一边输入一边筛选