同一单元格内容提取到不同列显示

叶落秋无言

烦请帮忙看下，一个单元格包含多个信息，怎么提取并单独显示几列？详见附件。谢谢各位技术大佬不吝赐教！

风中的我脸

b2=Textbetweens(A2,"】",$B$1,$C$1,$D$1)
textbetween = LAMBDA(v, d, ds, IFERROR(TEXTBEFORE(TEXTAFTER(v, d & "："), ds), ""));

Textbetweens = LAMBDA(val, del, delf, dels, delt,
    LET(
        resfirst, textbetween(val, delf, del),
        ressecond, textbetween(val, dels, del),
        resthird, textbetween(val, delt, del),
        res, HSTACK(resfirst, ressecond, resthird),
        res
    )
);

你是那块小饼干

1. =TRANSPOSE(INDEX(TEXTSPLIT(A2,"：","】",TRUE),,2))

复制代码

你是那块小饼干

1. =IFNA(VLOOKUP("*"&B$1,TEXTSPLIT($A2,"：","】",TRUE),2,0),"")

复制代码

左拉下拉

叶落秋无言

风中的我脸 发表于 2024-9-17 15:04
b2=Textbetweens(A2,"】",$B$1,$C$1,$D$1)
textbetween = LAMBDA(v, d, ds, IFERROR(TEXTBEFORE(TEXTAFTER ...

谢谢您，有点复杂，是python自定义公式吗？  phyton还不懂

sandays

=IFNA(REGEXEXTRACT($A2,B$1&"：\K\w+(?=】)"),"")

叶落秋无言

问题已解决，请忽略

叶落秋无言

你是那块小饼干 发表于 2024-9-17 15:55
左拉下拉

大神太牛掰了，解决问题了，谢谢

叶落秋无言

sandays 发表于 2024-9-17 16:00
=IFNA(REGEXEXTRACT($A2,B$1&"：\K\w+(?=】)"),"")

这个试了下 好像不行啊

mjm04

如果不要求严格对位（WPS正则，M365需要换函数名称）
=REGEXP(A2,"(?<=部门档案：|客商辅助核算：|发票号码辅助核算：)[A-Z一-龢\d]+")

=======================================================
如果严格对位，用下面这个，M365 与 WPS 均可用

B2单元格：
=IFNA(TEXTBEFORE(TEXTAFTER($A2,B$1&"："),"】"),"")
右拉、下拉