恳请大师们帮忙提供一个在指定命名的表格中寻找不同数据的难题

qiongmei6

我附件里我想在汇总表格里求得一个代码，在寻找同一个工作簿中的命名是“工资”或者“物贴”表格内的a：c列的数据（只能是在“工资”或者“物贴”表里寻找），如果在这几个表中a列和b列一致的，在汇总表里只显示一个数据，例如工资表中1234的单位是北京，物贴1中1234的单位也是北京，那么在汇总表中就只有一行单位是北京的1234，但是工资表中12345的单位是上海，物贴1中12345的单位是北京，那么在汇总表里12345的账号出现2次，一次是北京，一次是上海，目前的汇总表就是我希望用代码得到的结果，非常谢谢各位大师的帮忙。

Qs18

您物贴表有两个，具体是其中一个还是两个都要，

lsc900707

参考测试附件：

qiongmei6

Qs18 发表于 2024-9-16 20:42
您物贴表有两个，具体是其中一个还是两个都要，

物贴表在今后的有无数个，不一定是2个，凡是名字是工资和物贴表的都要

gwjkkkkk

Option Explicit
Sub TEST1()
    Dim ar, br, i&, j&, r&, wks As Worksheet, dic As Object, strJoin$
   
    Set dic = CreateObject("Scripting.Dictionary")
    With CreateObject("VBScript.RegExp")
        .Pattern = "工资|物贴"
        For Each wks In Worksheets
            If .test(wks.Name) Then
                With wks
                    r = .Cells(.Rows.Count, "A").End(xlUp).Row
                    br = .Range("A1:C" & r).Value
                    For i = 2 To UBound(br)
                        strJoin = ""
                        For j = 1 To UBound(br, 2)
                            strJoin = strJoin & "|" & br(i, j)
                        Next j
                        dic(strJoin) = Empty
                    Next i
                End With
            End If
        Next
    End With
   
    ReDim ar(1 To dic.Count, 1 To 3) As String
    For i = 0 To dic.Count - 1
        br = Split(dic.keys()(i), "|")
        For j = 1 To UBound(br)
            ar(i + 1, j) = br(j)
        Next j
    Next i
   
    With Worksheets("汇总")
        .[C1].CurrentRegion.Offset(1).Clear
        .[C2].Resize(UBound(ar), UBound(ar, 2)) = ar
        .Activate
    End With
    Beep
End Sub

gwjkkkkk

参与一下。。。