关于跨表查找写值问题，改代码

quqiyuan

改用字典+数组，速度提高1倍多，仅供参考。。。

sampsonpon

z865593849 发表于 2024-9-12 15:56
find 方法 ，2.9秒

实际带入是错误的，哪里有问题？

sampsonpon

quqiyuan 发表于 2024-9-12 15:59
改用字典+数组，速度提高1倍多，仅供参考。。。

如何在您的代码上进一步实现以下：

目前V列是通过VLOOKUP公式得到的
想直接得到V列值，也就是不用显示AD列值，
将AD列值先保存到数组里，再通过匹配"Vendor“里A列找到B列值直接写到V列

quqiyuan

sampsonpon 发表于 2024-9-13 09:41
如何在您的代码上进一步实现以下：

目前V列是通过VLOOKUP公式得到的

不难，稍作修改就可以了

quqiyuan

代码如下。。。。
Sub UpdateSKUList2()     'https://club.excelhome.net/thread-1701578-2-1.html 楼主13楼需要修改
    t = Timer
    Application.ScreenUpdating = False
    Dim sourceWorkbook As Workbook
    Dim targetWorksheet As Worksheet
    Dim sourceWorksheet As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim skuValue As Variant
    Dim sourceFilePath As String
    Set d = CreateObject("scripting.dictionary")
    ' 设置源工作簿的文件路径
'    sourceFilePath = "P:\PlG Files\test.xlsb"
    sourceFilePath = "K:\excelhome\test.xlsb"
    ' 以只读方式打开源工作簿
    Set sourceWorkbook = Workbooks.Open(sourceFilePath, ReadOnly:=True)
    Set sht = sourceWorkbook.Worksheets("Database")
    brr = Intersect(sht.UsedRange, sht.Columns("a:c"))
    For i = 1 To UBound(brr)
        If brr(i, 1) <> Empty Then d(brr(i, 1)) = i
    Next
    ' 设置目标工作表
    Set targetWorksheet = ThisWorkbook.Worksheets("LIST")
   
    ' 获取目标工作表的最后一行
    With targetWorksheet
        lastRow = .Cells(.Rows.Count, "B").End(xlUp).Row
        c = .Cells(1, .Columns.Count).End(1).Column
        arr = .Range(.[a1], .Cells(lastRow, c))
    End With
   
    ReDim crr(1 To lastRow - 1, 1 To 1)
   
    Set vendor = ThisWorkbook.Worksheets("Vendor")
    drr = vendor.UsedRange
   
    ' 遍历目标工作表的B列，查找匹配的SKU值并写入AD列
    For i = 2 To lastRow ' 假设从第2行开始，因为通常第一行是标题行
            If d.exists(arr(i, 2) & arr(i, 3)) Then
                crr(i - 1, 1) = Application.VLookup(brr(d(arr(i, 2) & arr(i, 3)), 3), drr, 2, 0)
            End If
    Next i
    targetWorksheet.[v2].Resize(lastRow - 1) = crr
    ' 关闭源工作簿，不保存更改
    sourceWorkbook.Close SaveChanges:=False
    MsgBox "共耗时： " & Timer - t
    Application.ScreenUpdating = True
    Set d = Nothing
End Sub

sunya_0529

用字典加数组，肯定比直接循环写入单元格要快得多。



另外，打开数据源文件“test.xlsb”，要省下不少时间——