员工工资单竖版变横版问题用公式解决一下

hxj119 · 发表于 2024-9-6 10:03

amwji 发表于 2024-9-6 09:33
=UNIQUE(A1:A54) 显示溢出

E列多余求的内容全部清空！！！

169119191 · 发表于 2024-9-6 10:16

F2=IFNA(LOOKUP(1,0/(($E2=$A$1:$A$54)*(DAY($C:$C)=F$1)),$B$1:$B$54),0)

高山磐石 · 发表于 2024-9-6 11:12

本帖最后由高山磐石于 2024-9-6 11:14 编辑

=DROP(REDUCE("",E2:E3,LAMBDA(XX,YY,VSTACK(XX,DROP(REDUCE("",SEQUENCE(31),LAMBDA(X,Y,HSTACK(X,XLOOKUP(YY&Y,A1:A51&DAY(C1:C51),B1:B51,"",0)))),,1)))),1)

这个公式你可能用不上，因为版本的问题，但终有一天会有用的。
E2:E3可以通过UNIQUE取得.行数也可以通过公式得到。

wgreen · 发表于 2024-9-6 15:17

#在这=PIVOTBY(A1:A54,DAY(C1:C54),B1:B54,SUM,0,0,,0)里快速回复#

我要成为专家 · 发表于 2024-9-6 16:48

=DROP(REDUCE(0,UNIQUE(A1:A54),LAMBDA(x,y,LET(s,TRANSPOSE(FILTER(B:C,A:A=y)),VSTACK(x,HSTACK(y,XLOOKUP(F1:AJ1,DAY(TAKE(s,-1)),TAKE(s,1),0)))))),1)

复制代码

动态数组，一步到位

你是那块小饼干 · 发表于 2024-9-7 16:00

=SUMPRODUCT((DAY($C$1:$C$54)=$F1)*($A$1:$A$54=$E2),$B$1:$B$54)

复制代码

你是那块小饼干 · 发表于 2024-9-7 16:05

=PIVOTBY(A1:A54,DAY(C1:C54),B1:B54,SUM)

复制代码

WPS版本

高山磐石 · 发表于 2024-9-7 16:32

溢出会不会是因为你没有清除第二行的内容。

一杯绿茶来了 · 发表于 2024-9-7 20:58

=SUMIFS($B:$B,$C:$C,"2024-8-"&F$1,$A:$A,$E2)

		自动登录	找回密码
密码			免费注册

[已解决] 员工工资单竖版变横版问题 用公式解决一下

[已解决] 员工工资单竖版变横版问题用公式解决一下