查找上级id并求和的问题

Lith1um

新人求助大佬。如图，每个返修单号都会关联一个父级单号，怎么才能找出来所有原始的父级单号，并将报废数量相加？

miaojohn45

复制父级单号列，去重，然后SUMIF条件求和。

高山磐石

个人认为，因为层级数不确定，解决方法是用VBA

高山磐石

tmplinshi

1. =LAMBDA(rg, LET(
   
2.     ids, LET(
   
3.         colA, INDEX(rg, , 1),
   
4.         colB, INDEX(rg, , 2),
   
5.         uniqB, UNIQUE(colB),
   
6.         TOCOL(IFNA(MATCH(uniqB, colA, 0) / 0, uniqB), 2)
   
7.     ),
   
8.     fn, LAMBDA(fn, id, [i], [p], LET(
   
9.         i, i + 1,
   
10.         a, INDEX(rg, i, 1),
    
11.         b, INDEX(rg, i, 2),
    
12.         p, IF(ISOMITTED(p), VSTACK(id), p),
    
13.         isMatch, ISNUMBER(MATCH(b, p, 0)),
    
14.         n, isMatch * INDEX(rg, i, 5),
    
15.         newP, IF(isMatch, VSTACK(p, a), p),
    
16.         IF(i < ROWS(rg), SUM(fn(fn, id, i, newP), n), n)
    
17.     )),
    
18.     HSTACK(ids, MAP(ids, LAMBDA(id, fn(fn, id))))
    
19. ))(A2:E11)

复制代码

只适用于上级 id 在前面的情况。例如把第8行“7, 1, 10, 2, 8”放在首行，会统计出错。

Excel 365 可用。WPS 不知道为什么不行。

Lith1um

tmplinshi 发表于 2024-9-4 21:28
只适用于上级 id 在前面的情况。例如把第8行“7, 1, 10, 2, 8”放在首行，会统计出错。

Excel 365  ...

十分感谢，但我纯刚上班的小白，我要先研究一下这个问题对于我来说看来是就算给我答案也看不懂的程度

Lith1um

高山磐石 发表于 2024-9-4 18:40

感谢感谢，我要研究一下，刚开始工作，这些函数我都没接触过，看的还是一头雾水

Lith1um

tmplinshi 发表于 2024-9-4 21:28
只适用于上级 id 在前面的情况。例如把第8行“7, 1, 10, 2, 8”放在首行，会统计出错。

Excel 365  ...

感谢，我要开始研究一下vba了，这个问题就算给我答案解法我也看不太懂

高山磐石

Lith1um 发表于 2024-9-5 09:16
感谢，我要开始研究一下vba了，这个问题就算给我答案解法我也看不太懂

问题其实很简单，但重要的是在基础阶段做正确，也就是用完整的数据库代替这样的流水账，这样远胜过很多EXCEL技巧。
比如：

一级     二级     三级
111       2          9
            5          8

这样就不用那么多的技巧了。

Lith1um

高山磐石 发表于 2024-9-5 09:54
问题其实很简单，但重要的是在基础阶段做正确，也就是用完整的数据库代替这样的流水账，这样远胜过很多EX ...

谢谢高手，完全从零开始研究了俩小时，看懂你的解法了，现在我已经完全会用函数解决这个问题了