研究了一下用代码获取VBA中的全部宏名称的方法

大灰狼1976

jaxxcyh 发表于 2024-8-29 15:28
能否用正则表达式来匹配出定义宏或函数的代码句子？
Ai提供了一个正则模式：
Regex.Pattern = "^\s*(Pu ...

建议采用perfect老师的处理方式，参考：
https://club.excelhome.net/forum ... amp;_dsign=ee4642c1
第5楼

jaxxcyh

大灰狼1976 发表于 2024-8-29 15:34
建议采用perfect老师的处理方式，参考：
https://club.excelhome.net/forum.php?mod=viewthread&tid=168 ...

感谢，他用CodeModule的procStartline函数得到宏(或函数)名称的所在行位置，前提是已经知道宏(函数)名称才行。这个方法用来判断一个宏(函数)名称是否存在是可以的，但要探查出所有的宏(函数)名称就行不通了。

大灰狼1976

jaxxcyh 发表于 2024-8-29 16:54
感谢，他用CodeModule的procStartline函数得到宏(或函数)名称的所在行位置，前提是已经知道宏(函数)名称 ...

好吧，有可能是我记错了。我看看有没有其他方法。

大灰狼1976

找到了一个完整的代码，遍历所有子程序和函数
Sub GetVBAProcedures()
    '声明访问Excel工作簿的变量
    Dim app As Excel.Application
    Dim wb As Excel.Workbook
    Dim wsOutput As Excel.Worksheet
    Dim sOutput() As String
    Dim sFileName As String
    '声明访问工作簿中宏的变量
    Dim vbProj As VBIDE.VBProject
    Dim vbComp As VBIDE.VBComponent
    Dim vbMod As VBIDE.CodeModule
    '声明其它变量
    Dim iRow As Long
    Dim iCol As Long
    Dim iLine As Integer
    Dim sProcName As String
    Dim pk As vbext_ProcKind
    Set app = Excel.Application
    '创建新工作簿用于输出数据
    Set wsOutput = app.Workbooks.Add.Worksheets(1)
    '遍历打开的所有工作簿
    For Each vbProj In app.VBE.VBProjects
        On Error Resume Next
        sFileName = vbProj.Filename
        If Err.Number <> 0 Then sFileName = "文件没有保存"
        On Error GoTo 0
        '初始化输出数组
        ReDim sOutput(1 To 2)
        sOutput(1) = sFileName
        sOutput(2) = vbProj.Name
        iRow = 0
        '检查是否为受保护的工程
        On Error Resume Next
        Set vbComp = vbProj.VBComponents(1)
        On Error GoTo 0
        If Not vbComp Is Nothing Then
            '遍历工程中的每个组件
            For Each vbComp In vbProj.VBComponents
                '找到代码模块
                Set vbMod = vbComp.CodeModule
                '浏览代码模块,查找程序
                iLine = 1
                Do While iLine < vbMod.CountOfLines
                    sProcName = vbMod.ProcOfLine(iLine, pk)
                    If sProcName <> "" Then
                        iRow = iRow + 1
                        ReDim Preserve sOutput(1 To 2 + iRow)
                        sOutput(2 + iRow) = vbComp.Name & ": " & sProcName
                        iLine = iLine + vbMod.ProcCountLines(sProcName, pk)
                    Else
                        '这行没有程序,到下一行
                        iLine = iLine + 1
                    End If
                Loop
                Set vbMod = Nothing
                Set vbComp = Nothing
            Next
        Else
            ReDim Preserve sOutput(1 To 3)
            sOutput(3) = "工程被保护"
        End If
        If UBound(sOutput) = 2 Then
            ReDim Preserve sOutput(1 To 3)
            sOutput(3) = "工程中没有代码"
        End If
        '定义输入位置并输出
        If Len(wsOutput.Range("A1").Value) = 0 Then
            iCol = 1
        Else
            iCol = wsOutput.Cells(1, wsOutput.Columns.Count).End(xlToLeft).Column + 1
        End If
        wsOutput.Cells(1, iCol).Resize(UBound(sOutput) + 1 - LBound(sOutput)).Value = WorksheetFunction.Transpose(sOutput)
        Set vbProj = Nothing
    Next
    wsOutput.UsedRange.Columns.AutoFit
End Sub

大灰狼1976

遍历所有打开的工作簿中所有子程序和函数获取名称。

大灰狼1976

我看网上原始发表者的ID含"perfect"，也许就是此论坛perfect131兄的杰作，感谢！

山海风云轩

jaxxcyh 发表于 2024-8-28 20:34
修改了一下程序，可以实现以下功能：
1.列出所有宏或函数的名称 - listMicro
2.删除指定宏 - delMicro( ...

学习一下