多列按照条件合并一列

人身娃娃1981

大神们，求助了。自己研究了半天只能完成部分需求。

目前有4列内容，列名分别是RetailGTIN, InnerGTIN，ShipperGTIN, 和EndDate。
希望把RetailGTIN, InnerGTIN， ShipperGTIN3列先按从左到右，再从上到下合并成一列。有个附加要求：就是过滤掉其对应的EndDate小于今天的值；只要EndDate是空白，或大于今天的值。我自己做的公式只能合并3列，但是不会加过滤条件。而且这4列的位置是不固定的，不一定在A，B，C，D这 个列上。所以要按照第一行的名字RetailGTIN, InnerGTIN， ShipperGTIN, 和EndDate来查询位置。
这是我的公式：

=LET(
    data, FromFS!$A$2:$AB$179,
    headers, FromFS!$A$1:$AB$1,
    includeCols, (headers="RetailGTIN") + (headers="InnerGTIN") + (headers="ShipperGTIN"),
    filteredData, FILTER(data, includeCols),
    textData, TOCOL(filteredData, 1),
    TEXT(textData, "00000000000000")
)

先谢谢大神了。附近样例已经上传。不胜感激。

沈默00

没太明白需求。。。。
目标不在固定列，是不是可以用match抓取列号

人身娃娃1981

谁能帮帮我啊？多谢啦。

无关岁月

添加一次筛选

1. =LET(
   
2.     data, FromFS!$A$2:$AB$179,
   
3.     headers, FromFS!$A$1:$AB$1,
   
4.     includeCols, (headers="RetailGTIN") + (headers="InnerGTIN") + (headers="ShipperGTIN"),
   
5.     filteredData, FILTER(FILTER(data, includeCols),(INDEX(data,,1)>TODAY())+(INDEX(data,,1)="")),
   
6.     textData, TOCOL(filteredData, 1),
   
7.     TEXT(textData, "00000000000000")
   

复制代码

人身娃娃1981

无关岁月 发表于 2024-8-19 11:57
添加一次筛选

无关岁月大神感谢了。针对目前这个sheet是好用的。但是我的4列不一定在a，b，c，d。顺序也有可能变化。中间还有可能还有其他列。所以需要按照行名来定位一下。您能再帮我一把吗？多谢，不胜感激。

无关岁月

人身娃娃1981 发表于 2024-8-19 13:30
无关岁月大神感谢了。针对目前这个sheet是好用的。但是我的4列不一定在a，b，c，d。顺序也有可能变化。中 ...

1. =LET(
   
2.     data, FromFS!$A$2:$AB$179,
   
3.     headers, FromFS!$A$1:$AB$1,
   
4.     includeCols, N(OFFSET(FromFS!A1,ROW(1:178),MATCH({"RetailGTIN","InnerGTIN","ShipperGTIN"},headers,)-1)),
   
5.     filteredData, FILTER(includeCols,(INDEX(data,,1)>TODAY())+(INDEX(data,,1)="")),
   
6.     textData, TOCOL(IF(filteredData,filteredData,x),2),
   
7.     TEXT(textData, "00000000000000")
   
8. )
   

复制代码

人身娃娃1981

无关岁月 发表于 2024-8-19 14:44

感谢感谢啊！

人身娃娃1981

自我回复一下吧，这个验证了可用：

=LET(
    data, FromFS!$A$2:$FW$179,
    headers, FromFS!$A$1:$FW$1,
    includeCols, (headers="RetailGTIN") + (headers="InnerGTIN") + (headers="ShipperGTIN"),
    endDateCol, MATCH("EndDate", headers, 0),
    filteredData, FILTER(FILTER(data, includeCols), (INDEX(data,,endDateCol)>TODAY()) + (INDEX(data,,endDateCol)="")),
    textData, TOCOL(filteredData, 1),
    TEXT(textData, "00000000000000")
)