单元格里面有文本的多组数字求和

无关岁月

1. =SUM(IFERROR(--MID(TEXT(MID(SUBSTITUTE(C2," ",REPT(" ",9)),ROW($1:$333),9),),2,8),0))

复制代码

ba3259878266

leepoison 发表于 2024-8-18 23:20
=SUM(--TEXTSPLIT(C2,TEXTSPLIT(C2,CHAR(SEQUENCE(10,,48)),,1),,1))

师傅 没有反应 谢谢

ba3259878266

hxj119 发表于 2024-8-18 23:00
OFFICE是啥版本的？

老师 专业增强版  2019

沈默00

=SUM(--REGEXP(C2,"[0-9]+"))
=SUM(--REGEXP(C2,"\d+"))

菜狗一只

1. =SUM(VALUE(LET(Y,TEXTSPLIT(C2,," "),RIGHT(Y,LEN(Y)-(LENB(Y)-LEN(Y))))))

复制代码

公式包含新函数，建议使用wps进行处理，公式使用前提是文本间有空格

安然祥和

=SUM(TEXT(MID(TEXT(MID(SUBSTITUTE(C2," ",REPT(" ",10)),ROW(1:100),10),),2,9),"0.00;!0;!0;!0")*1)

ba3259878266

安然祥和 发表于 2024-8-19 10:08
=SUM(TEXT(MID(TEXT(MID(SUBSTITUTE(C2," ",REPT(" ",10)),ROW(1:100),10),),2,9),"0.00;!0;!0;!0")*1)

谢谢 老师 好用  但是下拉多个单元格就不能用

ba3259878266

菜狗一只 发表于 2024-8-19 09:13
公式包含新函数，建议使用wps进行处理，公式使用前提是文本间有空格

谢谢老师  很好用  增加一项 空白单元格返回0

铁马金戈1970

=EVALUATE(SUBSTITUTE(TRIM(CONCAT(MIDB(C2,ROW($1:$50),1)))," ","+"))

以MIDB去除双字节汉字，然后将所有数值加起来，不知道能不能满足你的需要。

1786024734

1. =SUM(IFERROR(--MID(SUBSTITUTE(TRIM(CONCAT(MIDB(C2,ROW(1:99),1)))," ",REPT(" ",99)),ROW(1:99)*99-98,99),))

复制代码

如果支持【TEXTSPLIT】函数，可简化为

1. =SUM(--TEXTSPLIT(CONCAT(MIDB(C2,ROW(1:99),1))," ",,1))

复制代码