SORT(UNIQUE()) 去重排序后面的数字能1后为2吗？

再回首-沉默 · 发表于 2024-8-14 18:06

这个1.10.11.2可以让他1.2.3.4排吗？

无关岁月 · 发表于 2024-8-14 19:24

=UNIQUE(SORTBY(B1:B176,TEXTSPLIT(B1:B176,ROW(1:10)-1),1,--TEXTSPLIT(B1:B176,CHAR(ROW(65:90)),,1),1))

复制代码

jerrike · 发表于 2024-8-14 21:13

=UNIQUE(SORTBY(B1:B176,MAP(B1:B176,LAMBDA(a,CONCAT(TEXT(REGEXP(a,"[A-Z]+|\d+"),"00"))))))

复制代码

hxj119 · 发表于 2024-8-14 21:37

=LET(a,UNIQUE(TOCOL(B1:B999,3)),b,MAP(a,LAMBDA(y,VSTACK(IFERROR(REGEXP(y,"\d+")/1,0)))),c,MAP(a,LAMBDA(y,VSTACK(REGEXP(y,"[A-Z]+")))),SORTBY(a,c,1,b,1))

复制代码

ww87725244 · 发表于 2024-8-14 23:21

=LET(a,UNIQUE(B1:B176),SORTBY(a,LEFT(a,1),,--REGEXEXTRACT(a,"\d+"),1))

复制代码

sandays · 发表于 2024-8-15 07:37

=LET(a,UNIQUE(B1:B176),SORTBY(a,REGEXREPLACE(a,"\d",),,--REGEXEXTRACT(a,"\d+"),))

hugeinfo · 发表于 2024-8-15 07:52

本帖最后由 hugeinfo 于 2024-8-15 07:54 编辑

=UNIQUE(SORTBY(B1:B176,TEXTSPLIT(B1:B176,ROW(1:10)-1,),1,--SUBSTITUTES(B1:B176,TEXTSPLIT(B1:B176,ROW(1:10)-1,),""),1))

我要成为专家 · 发表于 2024-8-15 08:29

=let(s,uinque(b1:b176),m,substitutes(s,char(row(65:90)),""),sortby(s,s,,--m,-1))

part98 · 发表于 2024-8-15 09:23

=LET(s,UNIQUE(B1:B176),SORTBY(s,s,,--REGEXEXTRACT(s,"\d+"),))

秃头发师 · 发表于 2024-8-15 09:39

正好最后一个字母是Z

=LET(x,DROP(UNIQUE(B:B),-1),SORTBY(x,x,1,--TEXTAFTER(x,"Z"),-1))

		自动登录	找回密码
密码			免费注册

[求助] SORT(UNIQUE()) 去重排序后面的数字能1后为2吗？

评分

评分

评分