突然想到一个有意思的需求：随机生成10以内的减法题目

Michael.Deng · 发表于 2024-8-9 13:11

本帖最后由 Michael.Deng 于 2024-8-9 14:48 编辑

随机生成10以内的减法题目，结果如附件所示

在单元格中生成结果例如：9-6=
要求：
1、减数大于等于被减数，结果不能为负数；
2、结果可以为0，例如0-0=，1-1=，2-2=；
3、要随机生成；

4、纯函数，VBA和辅助列暂不考虑。

yibao2 · 发表于 2024-8-12 17:50

Michael.Deng 发表于 2024-8-12 13:43
没有TEXTJOIN函数

=SUBSTITUTE(SUBSTITUTE(TEXT(SUM(LARGE(IF({1,0},RANDBETWEEN(0,10),RANDBETWEEN(0,10)),{1,2})*{1,0.01}),"0.00"),".0","-"),".","-")&"="

满坛皆为吾师 · 发表于 2024-8-13 11:55

=TEXT(SUM(LARGE(RANDBETWEEN({0,0},9),{1,2})*10^{1,0}),"0-0=")

复制代码

Michael.Deng · 发表于 2024-8-9 13:49

乍一看很简单，仔细一想好难

无关岁月 · 发表于 2024-8-9 14:09

=TEXTJOIN("-",,SORT(RANDBETWEEN({0,0},10),,-1,1))&"="

复制代码

nightsun620 · 发表于 2024-8-9 14:16

=LET(x,RANDBETWEEN(0,9),y,RANDBETWEEN(0,x),x&"-"&y&"=")

复制代码

part98 · 发表于 2024-8-9 14:19

=TEXTJOIN("-",,SORT(RANDARRAY(2,,1,10,1),,-1))&"="

贱贱的七少爷 · 发表于 2024-8-9 14:38

增加了一点

Michael.Deng · 发表于 2024-8-9 14:39

part98 发表于 2024-8-9 14:19
=TEXTJOIN("-",,SORT(RANDARRAY(2,,1,10,1),,-1))&"="

感谢大佬。我版本太低了，没有sort函数

Michael.Deng · 发表于 2024-8-9 14:48

贱贱的七少爷发表于 2024-8-9 14:38
增加了一点

感谢大佬，有没有不用VBA和辅助列的解法

leepoison · 发表于 2024-8-9 17:13

这个我之前做过加减的

=LET(maxNumber,10,z,CHOOSE(RANDBETWEEN(1,2),"+","-"),IF(z="+",LET(x,RANDBETWEEN(0,maxNumber),y,RANDBETWEEN(0,MIN(maxNumber-x,maxNumber)),x&z&y),LET(x,RANDBETWEEN(0,maxNumber),y,RANDBETWEEN(0,MIN(x,maxNumber)),x&z&y)))

调整红色即可

yibao2 · 发表于 2024-8-10 10:33

本帖最后由 yibao2 于 2024-8-10 10:41 编辑

有textjoin函数不难：
=TEXTJOIN("-",1,LARGE(--MID(RANDBETWEEN(100,999),{2,3},1),{1,2}))&"="
数组
包含10：
=TEXTJOIN("-",1,LARGE(IF({1,0},RANDBETWEEN(0,10),RANDBETWEEN(0,10)),{1,2}))&"="

		自动登录	找回密码
密码			免费注册

[已解决] 突然想到一个有意思的需求：随机生成10以内的减法题目

评分

评分